Clojure 语言异常

Question

我一直在尝试实现垃圾邮件分类器。我写了一个函数来获得一些概率，但是当我用两个参数调用这个函数时，我得到 clojure.lang.ArityException “传递给函数的参数数量错误”。这是我的功能：

(defn weightedprob
  [f cat]
  (let [weight 1
        ap 0.5
        basicprob (atom 0)
        totals (atom 0)
        bp (atom 0)]
    (swap! basicprob #(fprob f cat))
    (swap! totals #(reduce + (vals (get @fc f))))
    (swap! bp #(/ (+ (* weight ap) (* totals basicprob)) (+ weight totals)))
    bp))

这是电话：

(weightedprob "money" "good")

现在可以了。如果您对如何实现此功能有更好的了解，我会很高兴看到这一点。这是有效的版本：

(defn weightedprob
  [f cat]
   (let [weight 1
   ap 0.5
   basicprob (atom 0)
   totals (atom 0)
   bp (atom 0)]
  (reset! basicprob (fprob f cat))
  (reset! totals (reduce + (vals (get @fc f))))
  (reset! bp (/ (+ (* weight ap) (* @totals @basicprob)) (+ weight 
  @totals)))
  @bp))

我一直在实现的 Python 中的函数如下所示：

  def weightedprob(self,f,cat,prf,weight=1.0,ap=0.5):    
      # Calculate current  probability    
      basicprob=prf(f,cat)
      # Count the number of times this feature has appeared in    
      # all categories    
      totals=sum([self.fcount(f,c) for c in self.categories()])
      # Calculate the weighted average    
      bp=((weight*ap)+(totals*basicprob))/(weight+totals)    
      return bp 

这是来自集体智慧书，第 6 章，文档过滤

没有原子的函数：

(defn weightedprob1
 [f cat]
  (let [weight 1
        ap 0.5
        basicprob (fprob f cat)
        totals (reduce + (vals (get @fc f)))
        bp (/ (+ (* weight ap) (* totals basicprob)) (+ weight totals))]
  bp))

Answer 1

您最初的问题是由 swap! 期望使用单个参数的函数引起的。您提供了一个不带任何参数的函数，因此出现了错误。

更正后的代码将是您已经发布的代码：

(defn weightedprob [f cat]
  (let [weight 1
        ap 0.5
        basicprob (atom 0)
        totals (atom 0)
        bp (atom 0)]
    (reset! basicprob (fprob f cat))
    (reset! totals (reduce + (vals (get @fc f))))
    (reset! bp (/ (+ (* weight ap) (* @totals @basicprob)) (+ weight @totals)))
    @bp))

不过，这根本不需要原子。原子主要只是用于管理线程之间的数据。你在这里根本不需要任何类型的突变。继续使用let：

(defn weightedprob [f cat]
  (let [weight 1
        ap 0.5
        basicprob (fprob f cat)
        totals (reduce + (vals (get @fc f)))]
   (/ (+ (* weight ap) (* totals basicprob)) (+ weight totals)))) 

目前还不清楚fc 是什么，但它可能也不需要是原子。