在 Clojure 中创建一个类似 Ruby 的 `binding.pry` 宏

Question

我一直在努力创建一个宏，它允许我将&env 中的任何内容动态绑定到binding 表单中，然后委托给pry 之类的函数来打开一个可以看到的REPL那些绑定&env 符号。

我的简单pry func，按预期工作

(defn pry []
  (print (str "pry(" *ns* ")> "))
  (flush)
  (let [expr (read)]
    (when-not (= expr :exit)
      (println (eval expr))
      (recur))))

使用pry 函数：

clojure-noob.core=> (def a 1)
#'clojure-noob.core/a
clojure-noob.core=> (pry)
pry(clojure-noob.core)> (+ a 1)
2
pry(clojure-noob.core)> :exit
nil
clojure-noob.core=>

我尝试创建binding 的动态调用：

(defmacro binding-pry []
  (let [ks (keys &env)]
    `(let [ks# '~ks
           vs# [~@ks]
           bs# (vec (interleave ks# vs#))]
       (binding bs# (pry)))))

但是，这会失败，因为内部符号 bs# 没有扩展为实际向量，而是生成的符号，binding 抛出了 clojure.core/binding requires a vector for its binding 异常。

clojure-noob.core=> (let [a 1 b 2] (binding-pry))
Syntax error macroexpanding clojure.core/binding at (/tmp/form-init14332359378145135257.clj:1:16).
clojure.core/binding requires a vector for its binding in clojure-noob.core:

clojure-noob.core=> 

带有调试打印的代码引用表单，打印时解析bs#符号，但我不知道在构造binding表单时如何使其解析为向量。

(defmacro binding-pry []
  (let [ks (keys &env)]
    `(let [ks# '~ks
           vs# [~@ks]
           bs# (vec (interleave ks# vs#))]
       (println bs#)
       `(binding bs# (pry)))))

clojure-noob.core=> (let [a 1 b 2] (binding-pry))
[a 1 b 2]
(clojure.core/binding clojure-noob.core/bs__2464__auto__ (clojure-noob.core/pry))
clojure-noob.core=>

我非常有信心我没有正确地解决这个问题，但我没有看到其他方法。

Answer 1

The Joy of Clojure 演示了一个 break 宏，它已经做到了这一点。我不能在这里复制它的源代码，因为它是 EPL 而不是 CC。但你可以在https://github.com/joyofclojure/book-source/blob/b76ef15/first-edition/src/joy/breakpoint.clj 看到它的来源。它还引用了contextual-eval 函数：https://github.com/joyofclojure/book-source/blob/b76ef15/first-edition/src/joy/macros.clj#L4-L7。

Answer 2

改进尝试的第一步可能是写作：

(defmacro binding-pry []
  (let [ks (keys &env)]
    `(binding [~@(interleave ks ks)] (pry))))

这仍然不起作用，因为binding 期望符号可以解析为现有的动态变量。为了解决这个问题，你可以让binding-pry 引入如下所示的变量：

(defmacro binding-pry []
  (let [ks (keys &env)]
    `(do
       ~@(map (fn [k] `(def ~(with-meta k {:dynamic true}))) ks)
       (binding [~@(interleave ks ks)] (pry)))))

但这可能会产生不良的副作用，例如使用新的变量名污染命名空间或使现有变量动态化。所以我更喜欢 amalloy 的回答中提到的方法，但更好地实现 eval-in-context（请参阅我的评论）。

要根据您的pry 函数编写一个独立的答案，我们首先定义eval-in，它在环境中评估表单：

(defn eval-in [env form]
  (apply
    (eval `(fn* [~@(keys env)] ~form))
    (vals env)))

然后让我们修改pry 以将环境作为参数并使用eval-in 代替eval：

(defn pry [env]
  (let [prompt (str "pry(" *ns* ")> ")]
    (loop []
      (print prompt)
      (flush)
      (let [expr (read)]
        (when-not (= expr :exit)
          (println (eval-in env expr))
          (recur))))))

一个等价的、不那么原始的版本可能是：

(defn pry [env]
  (->> (repeatedly (let [prompt (str "pry(" *ns* ")> ")]
                     #(do (print prompt) (flush) (read))))
       (take-while (partial not= :exit))
       (run! (comp println (partial eval-in env)))))

现在我们可以定义binding-pry如下：

(defmacro binding-pry []
  `(pry ~(into {}
           (map (juxt (partial list 'quote) identity))
           (keys &env))))

最后，这是binding-pry 的直接/“意大利面条”实现：

(defmacro binding-pry []
  (let [ks (keys &env)]
    `(->> (repeatedly (let* [prompt# (str "pry(" *ns* ")> ")]
                        #(do (print prompt#) (flush) (read))))
          (take-while (partial not= :exit))
          (run! (comp println
                      #((eval `(fn* [~~@(map (partial list 'quote) ks)] ~%))
                        ~@ks))))))