使用doseq遍历地图

Question

我是 Clojure 的新手，我正在从 labrepl 做一些基本的事情，现在我想编写一个函数，将某些字母替换为其他字母，例如：elosska → elößkä。

这是我写的：

(ns student.dialect (:require [clojure.string :as str]))
(defn germanize
  [sentence]
  (def german-letters {"a" "ä" "u" "ü" "o" "ö" "ss" "ß"})
  (doseq [[original-letter new-letter] german-letters]
    (str/replace sentence original-letter new-letter)))

但它并没有像我预期的那样工作。你能帮帮我吗？

Answer 1

这是我的看法，

(def german-letters {"a" "ä" "u" "ü" "o" "ö" "ss" "ß"}) (defn germanize [s] (reduce (fn[sentence [match replacement]] (str/replace sentence match replacement)) s german-letters))

(germanize "elosska")

Answer 2

这里有两个问题：

1. doseq 不保留由其评估创建的列表头，因此您不会得到任何结果
2. str/replace 处理单独的文本副本，产生 4 种不同的结果 - 您可以通过将 doseq 替换为 for 来检查这一点，您将获得包含 4 个条目的列表。

您的代码可以通过以下方式重写：

(def german-letters {"a" "ä" "u" "ü" "o" "ö" "ss" "ß"})
(defn germanize [sentence]
  (loop [text sentence
         letters german-letters]
    (if (empty? letters)
      text
      (let [[original-letter new-letter] (first letters)]
        (recur (str/replace text original-letter new-letter)
               (rest letters))))))

在这种情况下，会收集中间结果，因此所有替换都应用于相同的字符串，从而生成正确的字符串：

user> (germanize "elosska")
"elößkä"

附：也不建议在函数中使用def - 最好将其用于顶级表单

Answer 3

当然，Alex 已经使用doseq 正确回答了关于原始问题的问题...但我发现这个问题很有趣，并想看看一个更“实用”的解决方案是什么样的。我的意思是不使用循环。

我想出了这个：

(ns student.dialect (:require [clojure.string :as str]))

(defn germanize [sentence]
  (let [letters {"a" "ä" "u" "ü" "o" "ö" "ss" "ß"}
        regex (re-pattern (apply str (interpose \| (keys letters))))]
    (str/replace sentence regex letters)))

产生相同的结果：

student.dialect=> (germanize "elosska")
"elößkä"

regex (re-pattern... 行简单地计算为#"ss|a|o|u"，如果输入为显式字符串，它会更简洁，更易于阅读，但我认为最好只定义一个德语字母。