在clojure中，如何将宏应用于列表？

Question

在clojure 中，apply 不能应用于宏。例如(apply and [true false]) 引发异常。我正在考虑以下解决方法：

(defmacro apply-macro[func args] `(~func ~@args))

乍一看，它似乎工作得很好：

(apply-macro and [true 5]); 5
(apply-macro and [true 5 0]); 0
(let [a 0] (apply-macro and [true a])); 0

但是，当我将一个指向向量的变量传递给它时，它崩溃了。

(let [a [true]] (apply-macro and a));  java.lang.IllegalArgumentException:
   ;Don't know how to create ISeq from: clojure.lang.Symbol

多么令人失望！！！！

知道如何修复apply-macro吗？

Answer 1

你没有。

宏在评估/编译期间扩展，而不是在运行时扩展，因此它们可以使用的唯一信息是传入的 args，但不是 args 在运行时评估的内容。这就是文字向量起作用的原因，因为该文字向量在编译时就在那里，但 a 只是一个符号；它只会在运行时评估为向量。

要使列表具有类似and 的行为，请使用(every? identity coll)。

要使列表具有类似or 的行为，请使用(some identity coll)。

Answer 2

问题在于a 在编译时只是一个符号。因此，编译时宏无法查看它包含的内容并进行必要的扩展。因此，您需要在运行时使用eval 展开宏。

这样做的一种方法是将宏包装在一个调用 eval 的函数中，这可以通过这个方便的“functionize”宏来完成：

(defmacro functionize [macro]
  `(fn [& args#] (eval (cons '~macro args#))))

(let [a [true]] (apply (functionize and) a))
=> true

如果你喜欢，你也可以根据 functionize 来定义 apply-macro：

(defmacro apply-macro [macro args]
   `(apply (functionize ~macro) ~args))

(let [a [true false]] (apply-macro and a))
=> false

说了这么多，我仍然认为最好的办法是在真正不需要宏时完全避免使用宏：它们会增加额外的复杂性，最好留给真正需要编译时代码生成的情况。在这种情况下你不需要：Alex Taggart's answer 给出了一个很好的例子，说明如何在没有任何宏的情况下实现类似的目标，这在大多数情况下可能更合适。

Answer 3

将 args 应用于条件宏时，例如 or、case、cond 和 condp。您可以使用some、every 和partition 函数。这些示例中省略了单个 else 子句，但可以很容易地添加

;apply to the 'or' macro
(some identity [nil false 1 2 3])
=> 1

;apply to the 'case' macro.
(some
  (fn [[case value]]
    (and (= case 2) value))
  (partition 2 [1 "one" 2 "two" 3 "three"]))
=> "two"

;apply to the 'cond' macro
(some
  (fn [[case value]]
    (and case value))
  (partition 2 [false "one" true "two" false "three" :else "four"]))
=> "two"

;apply to the 'condp' macro
(let [[f v & args] [= 2 1 "one" 2 "two" 3 "three"]]
  (some
    (fn [[case value]]
      (and (f case v) value))
    (partition 2 args)))

every? 可用于and 宏

;apply to the 'and' macro
(every? identity [true true true])
=> true

Answer 4

当然，正确的答案是不要这样做。但是，因为我无法抗拒一个好的 hack：

(defmacro apply-macro
  "Applies macro to the argument list formed by prepending intervening
  arguments to args."
  {:arglists '([macro args]
               [macro x args]
               [macro x y args]
               [macro x y z args]
               [macro a b c d & args])}
  [macro & args+rest]
  (let [args (butlast args+rest)
        rest-args (eval (last args+rest))]
    `(eval
       (apply (deref (var ~macro))
              '(~macro ~@args ~@rest-args)
              nil
              ~@(map #(list 'quote %) args)
              '~rest-args))))

用法：

hackery> (->> (range 5) rest rest rest rest)
(4)
hackery> (apply-macro ->> (range 5) (repeat 4 'rest))
(4)

资格：

1. 宏不应被引用，并且中间的参数未经计算地传递给宏。但是，“rest”参数被评估，并且必须评估为符号或形式的列表，每个符号或形式都将不经评估地传递给宏。
2. 这不适用于使用 &env 参数的宏。

Answer 5

这种方法如果参数列表可以有无限长度则不起作用，但如果您只需要应用到长度不超过n 的列表，您可以使用n 创建一个包装函数艺人：

user> (defmacro foo [& rest] `(println ~@rest))
#'user/foo
user> (apply foo [1 2])
CompilerException java.lang.RuntimeException: Can't take value of a macro: #'user/foo, compiling:(*cider-repl repo*:865:7) 
user> (defn foo-up-to-ten-args
  ([a]                   (foo a))
  ([a b]                 (foo a b))
  ([a b c]               (foo a b c))
  ([a b c d]             (foo a b c d))
  ([a b c d e]           (foo a b c d e))
  ([a b c d e f]         (foo a b c d e f))
  ([a b c d e f g]       (foo a b c d e f g))
  ([a b c d e f g h]     (foo a b c d e f g h))
  ([a b c d e f g h i]   (foo a b c d e f g h i))
  ([a b c d e f g h i j] (foo a b c d e f g h i j)))
#'user/foo-up-to-ten-args
user> (apply foo-up-to-ten-args [1 2])
1 2
nil
user> (apply foo-up-to-ten-args (range 0 10))
0 1 2 3 4 5 6 7 8 9
nil
user> (apply foo-up-to-ten-args (range 0 11))
ArityException Wrong number of args (11) passed to: user/foo-up-to-ten-args  clojure.lang.AFn.throwArity (AFn.java:429)

在我的情况下，这在没有 eval 的情况下完成了我所需要的。