FSharp：使用泛型进行类型推断

Question

我不明白为什么下面的代码不能编译

module GenericsTest = 
    open System

    type Dog = {
        name:string
    }

    type Apple = {
        size:int
    }

    let get<'a> (id:string) =
        Activator.CreateInstance<'a>()

    let creatorInferred getAsParam = 
        let apple = {
            name = getAsParam "some-apple"
        }

        let dog = {
            size = getAsParam "some-dog"
        }
        (apple, dog)

    let creatorWithTypeAnnotation (getAsParam:string->'a) = 
        let apple = {
            name = getAsParam "some-apple"
        }

        let dog = {
            size = getAsParam "some-dog"
        }
        (apple, dog)

如果您查看 2“创建者...”函数 - 它们都给出编译错误..

这个表达式应该有 int 类型...但是这里有 输入字符串

我可以看到 F# 将 getAsParam 方法的返回类型推断为 int，因为它是它遇到的第一个。但是，为什么它不决定使用泛型返回类型呢？

如您所见，我已尝试在 creatorWithTypeAnnotation 方法中进行函数签名 - 但这没有任何影响。

我被难住了！我如何强制它识别 getAsParam 函数应该返回一个泛型？

Answer 1

这里是一个快速的 F# 交互式会话，我的意思是 使用接口作弊（它必须是某种 member - 所以它可以是类上的一个方法当然也是）：

> type IParam = abstract getParam : string -> 'a;;                              

type IParam =
  interface
    abstract member getParam : string -> 'a
  end

> let createWith (p : IParam) : int*bool = (p.getParam "a", p.getParam "b");;            

val createWith : p:IParam -> int * bool

> let test = { new IParam with member __.getParam s = Unchecked.defaultof<_> };;

val test : IParam

> createWith test;;                                                             
val it : int * bool = (0, false)

您可能会发现实现IParam 的一些更明智 实例并不容易；)

Answer 2

正如 Carsten 所暗示的，类型变量都是在编译时解析的。如果将getAsParam 定义为string -> 'a，则不会阻止'a 在编译时被解析。因为它不能在编译时解析为两种不同的类型，所以编译失败。

考虑你的例子：

let creatorWithTypeAnnotation (getAsParam:string->'a) = 
    let apple = {
        name = getAsParam "some-apple"
    }

    let dog = {
        size = getAsParam "some-dog"
    }

这也可以这样声明（我将使用'A 而不是'a，因为预期的约定是小写类型变量用于编译器推断的类型）：

let creatorWithTypeAnnotation<'A> (getAsParam:string->'A) = 
    let apple = {
        name = getAsParam "some-apple"
    }

    let dog = {
        size = getAsParam "some-dog"
    }

现在应该清楚为什么代码无法编译了。