在 VBA 中为 Microsoft Access 使用通配符

Question

让我们先说我的代码知识充其量是有限的。我通常理解这些概念，但从来没有很好地实施它们。也就是说，这里是我的一个项目中的一个 sn-p 代码。

Option Compare Database
Private Sub Form_Current()
If IsNull(Me![OPT-78 (5900EL)]) Then
    Me![OPT-78 (5900EL)].Visible = False
    Me![OPT-78 (5900EL) Label].Visible = False
Else
    Me![OPT-78 (5900EL)].Visible = True
    Me![OPT-78 (5900EL) Label].Visible = True
End If
If IsNull(Me![OPT-78 (7900EL)]) Then
    Me![OPT-78 (7900EL)].Visible = False
    Me![OPT-78 (7900EL) Label].Visible = False
Else
    Me![OPT-78 (7900EL)].Visible = True
    Me![OPT-78 (7900EL) Label].Visible = True
End If
If IsNull(Me![OPT-152 (4310B)]) Then
    Me![OPT-152 (4310B)].Visible = False
    Me![OPT-152 (4310B) Label].Visible = False
Else
    Me![OPT-152 (4310B)].Visible = True
    Me![OPT-152 (4310B) Label].Visible = True
End If

它位于“当前”事件的表单内。现在我知道通配符可以将所有这些 if then else 语句限制为一个简单优雅的单 if 语句解决方案，但我无法让它们工作。我试过 *、%、__ 和 ?，但没有运气。还有更多 if else 语句需要编写，所以我希望有一个更清洁的解决方案。

谢谢！

Answer 1

我首先创建一个 Sub 来处理设置可见性：

Sub SetVis(controlName as String)
   Dim vis as Boolean
   vis = Not IsNull(Me.Controls(controlName))
   Me.Controls(controlName).Visible = vis
   Me.Controls(controlName & " Label").Visible = vis
End sub

然后你可以从一个循环中驱动那个 sub，也许通过循环表单的 Controls 集合来找到感兴趣的那个。

Dim c
For Each c in Me.Controls
    'some If statement here to see if this is a control you're interested in
    'Might also want to check that the control type is a textbox so you can
    '  skip the labels
    If c.Name like "OPT*" And Not c.Name like "*Label" Then
        SetVis CStr(c.Name)
    End if
Next c

或基于固定名称数组的简单循环：

Dim c
For Each c In Array("OPT-78 (5900EL)", "OPT-78 (7900EL)", "OPT-152 (4310B)") 
    SetVis CStr(c)
Next c