批处理文件 - 替换 txt 文件中的关键字

Question

我正在尝试制作一些 BAT 文件，这些文件将扫描所有扩展名为 .txt 的文件，列出它们并替换多个关键字。我不知道txt文件名是什么。

这是我得到的：

@echo off

setlocal enabledelayedexpansion

set /a counter=1
set "SEARCH_A=KEYWORD1"
set "REPLACE_A=REPLACED1"
set "SEARCH_B=KEYWORD2"
set "REPLACE_B=REPLACED2"
set "newfile=Output.txt"

for /r %%i in (*.txt) do (

echo %%~nxi>> search_result.txt 

set "textfile=%%~nxi"
set "newfile=Output.txt"

(for /f "delims=" %%j in (!textfile!) do (
    set "line=%%j"
    setlocal enabledelayedexpansion
    set "line=!line:%SEARCH_A%=%REPLACE_A%!"
    set "line=!line:%SEARCH_B%=%REPLACE_B%!"
    echo(!line!
    endlocal
))>"%newfile%"

del !textfile!

rename %newfile%  !textfile!  

set /a counter=!counter!+1    


)

endlocal

而且它确实有效。我有两个问题：

• 关键字替换不适用于名称中有两个单词且中间有空格的 TXT 文件。有什么办法可以解决吗？
• 它还会检查目录中比 .bat 文件级别低的文件。如何限制它只检查与 .bat 相同级别的文件？

请帮助我。顺便说一句，我是个菜鸟。

Answer 1

将所有（可能）包含空格的文件/文件夹名括在引号中（更好：习惯于将所有文件/文件夹名括在引号中）：

(for /f "usebackq delims=" %%j in ("!textfile!") do (

（需要usebackq 来实际处理文本文件，而不仅仅是它的名称字符串）

del "!textfile!"
rename "%newfile%"  "!textfile!" 

for /r %%i in (*.txt) do (: /r 表示“递归”（包括子目录）。只需跳过 /r 即可仅处理当前文件夹而不处理子文件夹。