VBA Excel获取文件路径 - 不工作

Question

我一直在使用以下代码在 Excel 中指定文件夹路径：

Set diaFolder = Application.FileDialog(msoFileDialogFolderPicker)
diaFolder.AllowMultiSelect = False
diaFolder.Show

我会将 pdf 文件（通过 VBA 代码）导出到该路径。当我在 Windows XP 上运行 Excel 2007 时，这段代码可以完美运行。我最近升级了我的操作系统和 Office 版本，现在我在 Windows 7 上运行了 Excel 2010。代码不再像以前那样工作，问题是每次运行代码时路径都会不断上移一级。

例如，假设我选择以下路径：

\users\AK\Desktop\Projects\ProjectM

实际的pdf保存在\users\AK\Desktop\Projects\

如果我选择：\users\AK\Desktop\Projects\ pdf保存在\users\AK\Desktop\

如果我继续运行代码，它总是会向上跳一级，所以假设我按顺序运行它 3 次（每次不选择我的路径），我的 pdf 文件将存储在：\users\AK\

我不知道是 Excel 2010 问题还是 Windows 7 问题。有人遇到过吗？

编辑：包含完整代码：

Private Sub CODERUN()
    ' Define values
    FN_A = Cells(2, 2).Value

    ' Print PDF version
    Set diaFolder = Application.FileDialog(msoFileDialogFolderPicker)
    diaFolder.AllowMultiSelect = False
    diaFolder.Show

    ' Print PDF version
    Sheets("Part A").Select
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, filename:=FN_A & "_A", _
                                    Quality:=xlQualityStandard, _
                                    IncludeDocProperties:=True, _
                                    IgnorePrintAreas:=False, _
                                    OpenAfterPublish:=False
End Sub

Answer 1

我理解您的问题，因为我遇到了同样的问题。我相信你的问题是，如果你运行你拥有的代码，然后在对话框上点击取消或确定，下次你运行代码时，初始路径会比之前的初始路径高一个级别。发生这种情况的原因是，Dialog 没有添加尾随 \，然后将路径截断到下一个 \。因此，每次使用对话框时，您都会在路径中失去一个关卡。

以下代码应该适合您，您可以接受或取消，直到您满意为止，而无需更改初始目录。

Private Sub CODERUN()
    Dim sFilePath as String

    ' Define values
    FN_A = Cells(2, 2).Value

    ' Print PDF version
    With Application.FileDialog(msoFileDialogFolderPicker)
        .AllowMultiSelect = False
        If .Show = -1 Then
            sFilePath =  .SelectedItems(1) & "\"
            .InitialFileName = sFilePath  '<--Remove this line to see the problem
        End If
    End With

    ' Print PDF version
    Sheets("Part A").ExportAsFixedFormat Type:=xlTypePDF, filename:=sFilePath & FN_A & "_A", _
                                    Quality:=xlQualityStandard, _
                                    IncludeDocProperties:=True, _
                                    IgnorePrintAreas:=False, _
                                    OpenAfterPublish:=False
End Sub