为什么这个函数的pointfree版本看起来像这样？

Question

我一直在玩 Haskell，包括练习以无点形式编写函数。这是一个示例函数：

dotProduct :: (Num a) => [a] -> [a] -> a
dotProduct xs ys = sum (zipWith (*) xs ys)

我想以无点形式编写此函数。这是我在其他地方找到的示例：

dotProduct = (sum .) . zipWith (*)

但是，我不明白为什么无点表单看起来像 (sum .) . zipWith (*) 而不是 sum . zipWith (*)。为什么 sum 在括号中，并且有 2 个组合运算符？

Answer 1

dotProduct xs ys = sum (zipWith (*) xs ys)             -- # definition

dotProduct xs    = \ys -> sum (zipWith (*) xs ys)      -- # f x = g <=> f = \x -> g
                 = \ys -> (sum . (zipWith (*) xs)) ys  -- # f (g x) == (f . g) x
                 = sum . (zipWith (*) xs)              -- # \x -> f x == f
                 = sum . zipWith (*) xs                -- # Precedence rule

dotProduct       = \xs -> sum . zipWith (*) xs         -- # f x = g <=> f = \x -> g
                 = \xs -> (sum .) (zipWith (*) xs)     -- # f * g == (f *) g
                 = \xs -> ((sum .) . zipWith (*)) xs   -- # f (g x) == (f . g) x
                 = (sum .) . zipWith (*)               -- # \x -> f x == f

---

(sum .) 是一个部分。它被定义为

(sum .) f = sum . f

任何二元运算符都可以这样写，例如map (7 -) [1,2,3] == [7-1, 7-2, 7-3].

Answer 2

KennyTM 的回答非常好，但我还是想提供另一种观点：

dotProduct = (.) (.) (.) sum (zipWith (*))

• (.) f g 将f 应用于g 给定一个参数的结果
• 在给定两个参数的情况下，(.) (.) (.) f g 将 f 应用于 g 的结果
• (.) (.) ((.) (.) (.)) f g 在给定三个参数的情况下将 f 应用于 g 的结果
• ...
• 可以执行(.~) = (.) (.) (.)、(.~~) = (.) (.) (.~)、(.~~~) = (.) (.) (.~~) 和现在let foo a b c d = [1..5]; (.~~~) sum foo 0 0 0 0 的结果为15。
  • 但我不会这样做。它可能会使代码不可读。点到为止。
• Conal 的TypeCompose 提供了(.) 的同义词result。也许这个名字更有助于理解正在发生的事情。
  • fmap 也可以代替 (.)，如果导入相关实例（import Control.Applicative 会这样做），但它的类型更通用，因此可能更令人困惑。
• Conal 的“融合”概念（不要与“融合”的其他用法混淆）有点相关，恕我直言，提供了一种组合函数的好方法。更多详情this long Google Tech Talk that Conal gave