Excel 查找多个范围内的 IP 地址

Question

我正在尝试为A 列找到一个公式，该公式将检查B 列中的IP 地址，并查找它是否属于其他两列C 和@987654324 中的2 个地址范围（或之间） @。

例如

     A           B             C             D
+---------+-------------+-------------+------------+
| valid?  | address     | start       | end        |
+---------+-------------+-------------+------------+
| yes     | 10.1.1.5    | 10.1.1.0    | 10.1.1.31  |
| Yes     | 10.1.3.13   | 10.1.2.16   | 10.1.2.31  |
| no      | 10.1.2.7    | 10.1.1.128  | 10.1.1.223 |
| no      | 10.1.1.62   | 10.1.3.0    | 10.1.3.127 |
| yes     | 10.1.1.9    | 10.1.4.0    | 10.1.4.255 |
| no      | 10.1.1.50   | …           | …          |
| yes     | 10.1.1.200  |             |            |
+---------+-------------+-------------+------------+

这应该代表一个具有 4 列标题和 7 行的 Excel 表格作为示例。 我可以使用

进行横向检查

=IF(AND((B3>C3),(B3 < D3)),"yes","no")

它只根据它旁边的范围检查 1 个地址。 我需要一些东西来检查所有范围的 1 IP 地址。即第 1 到 100 行。

这是根据路由检查访问列表规则，看看我是否可以消除冗余规则......但如果我能实现它还有其他用途。 为了让它更加特别，我不能使用 VBA 宏来完成它。

我正在考虑某种索引匹配以在数组中查找它，但不确定如何应用它。我什至不知道它是否可以完成。祝你好运。

Answer 1

好的，所以自从我最初发表评论以来，我一直在跟踪这个问题，但没有花时间回答，因为就像 Lana B：

我喜欢一个很好的谜题，但如果我必须继续猜测，这不是很好地利用时间

感谢 Lana 在这个问题上的耐心和努力。

但是，IP 寻址是我经常处理的事情，所以为了我自己的利益，我决定解决这个问题。另外，没有冒犯，但是获取开头的 MIN 和结尾的 MAX 是错误的。这不会考虑 IP 白名单中的空白。正如我所提到的，这需要 15 个辅助列，而我的结果只是 1 或 0 分别对应于 In 或 Out。这是一个屏幕截图（每列下方显示的公式）：

F2:J2 中的公式为：

=NUMBERVALUE(MID(B2,1,FIND(".",B2)-1))              
=NUMBERVALUE(MID(B2,FIND(".",B2)+1,FIND(".",B2,FIND(".",B2)+1)-1-FIND(".",B2)))         
=NUMBERVALUE(MID(B2,FIND(".",B2,FIND(".",B2)+1)+1,FIND(".",B2,FIND(".",B2,FIND(".",B2)+1)+1)-1-FIND(".",B2,FIND(".",B2)+1)))        
=NUMBERVALUE(MID(B2,FIND(".",B2,FIND(".",B2,FIND(".",B2)+1)+1)+1,LEN(B2)))  
=F2*256^3+G2*256^2+H2*256+I2

是的，我使用公式而不是“文本到列”来自动化将更多信息添加到“活”工作表的过程。

L2:P2 中的公式相同，只是将B2 替换为C2。

R2:V2中的公式也一样，只是将B2替换为D2。

X2 的公式是

=SUMPRODUCT(--($P$2:$P$8<=J2)*--($V$2:$V$8>=J2))

我还在A 列中复制了您原来的“有效”集，您会看到它与我的结果相符。

Answer 2

您将需要辅助列。

• 如图所示组织数据。
• 将地址、开始和结束以逗号分隔成列（功能区菜单 Data=>Text To Columns）。
• 在开始/结束部分之上，计算所有拆分文本部分的 MIN FOR START 和 MAX FOR END（即 MIN(K5:K1000)。

公式：

有效性公式 - 复制到单元格 D5，然后向下拖动：

=IF(AND(B6>$I$1,B6<$O$1),"In",
   IF(OR(B6<$I$1,B6>$O$1),"Out",
     IF(B6=$I$1,
       IF(C6<$J$1, "Out",
         IF( C6>$J$1, "In",
           IF( D6<$K$1,  "Out",
             IF( D6>$K$1, "In",
               IF(E6>=$L$1, "In", "Out"))))),
     IF(B6=$O$1,
       IF(C6>$P$1, "Out",
         IF( C6<$P$1, "In",
           IF( D6>$Q$1,  "Out",
             IF( D6<$Q$1, "In",
               IF(E6<=$R$1, "In", "Out") ))))   )
 )))