递归查找包含子字符串的字符串的索引

Question

我试图在包含某个子字符串的列表的上下文中查找字符串的索引，但无济于事。我不确定如何将整个未触及的数组作为参数传递给递归函数中的另一个函数。这是我的方法：

find' :: [String] -> Maybe Int
find' [] = error "List is empty"
find' [x] = return maybe 0
find' (x:xs)
    | "HU" `isInfixOf` x = return elemIndex x (x:xs)
    | otherwise = checkTail
    where checkTail = find' xs

错误是：

 * Couldn't match type `[[String]] -> Maybe Int' with `Maybe Int'
  Expected type: String -> [String] -> Maybe Int
    Actual type: String -> [String] -> [[String]] -> Maybe Int
* The function `return' is applied to three arguments,
  but its type `([String] -> [[String]] -> Maybe Int)
                -> String -> [String] -> [[String]] -> Maybe Int'
  has only four
  In the expression: return elemIndex x (x : xs)
  In an equation for find':
      find' (x : xs)
        | "HU" `isInfixOf` x = return elemIndex x (x : xs)
        | otherwise = checkTail
        where
            checkTail = find' xs

   | "HU" `isInfixOf` x = return elemIndex x (x:xs)
                      ^^^^^^^^^^^^^^^^^^^^^^^^^

我真的不明白错误以及为什么它不匹配，因为在这两种情况下我都返回一个可能的 int。但是，正如我所提到的，我不确定 (x:xs) 是否实际上意味着参数的整个列表。 澄清一下，我试图从字符串列表中找到字符串的索引。

Answer 1

首先，maybe 本身就是一个函数；它的作用与问题无关。可以这么说，return 0 做你想做的事：它从函数返回 Just 0：

find' :: [String] -> Maybe Int
find' [] = Nothing
find' [x] = return 0 -- equivalent to find' [x] = Just 0

(注意Nothing的使用；如果你要引发错误，没有理由使用Maybe Int而不是Int作为返回类型。另外，没有理由使用return Just，因为您不是在这里尝试支持任意 monad。）

此外，elemIndex已经返回一个Maybe Int类型的值；您不需要使用 return 函数，该函数将值包装在另一层中，生成 Maybe (Maybe Int) 值，这不是您想要的。

find' (x:xs)
    | "HU" `isInfixOf` x = elemIndex x (x:xs)
    | otherwise = find' xs

最后一个问题：如果"HU" 不存在于列表的第一个元素中，则只需在列表的尾部调用find' 是正确的。但是，您需要将 1 添加到该返回值以补偿传递较短的参数。 （这也意味着您不需要elemIndex，因为您总是在当前列表的头部找到"HU"。）

find' (x:xs)
    | "HU" `inInfixOf` x = Just 0
    | otherwise = fmap (1+) (find' xs)

你需要使用fmap; find' 返回 Maybe Int，而不是 Int，因此 1 + find' xs 本身不起作用。

这也意味着您可以删除 [x] 的特殊情况，因为它是在列表头部找到搜索字符串之后得出的。整个函数只是

find' :: [String] -> Maybe Int
find' [] = Nothing
find' (x:xs)
    | "HU" `isInfixOf` x = Just 0
    | otherwise = fmap (1+) (find' xs)

---

处理整个列表的一种方法是一次搜索整个列表，然后在结果布尔值列表中找到（第一次）出现的 True。

find'' :: [String] -> Maybe Int
find'' xs = elemIndex True (map ("HU" `inInfixOf`) xs)
-- or find'' = elemIndex True . map ("HU" `inInfixOf`)
-- or find'' = findIndex ("HU" `inInfixOf`)