如何更改 Groovy 脚本的默认闭包解析策略？

Question

我正在编写一个包含许多全局属性和闭包的大型 Groovy 脚本。所有闭包都用于向现有类添加新方法，例如：

myProperty = 'foo'
// ...more script code...

class MyClass {
    def myProperty = 'default'
}
// ...more script code...

MyClass.metaClass.evaluate = { ->
    myProperty = 'bar'
}

def mc = new MyClass()
mc.evaluate()
println mc.myProperty // prints out "default" instead of "bar"

我的意图是让闭包的 myProperty 引用委托类的 myProperty 而不是全局的。我找到了几种方法来解决这个问题：

1) 在闭包中显式取消引用delegate：

MyClass.metaClass.evaluate = { ->
    delegate.myProperty = 'bar'
}

def mc = new MyClass()
mc.evaluate()
println mc.myProperty // prints out "bar" as desired

2) 将闭包的解析策略设置为DELEGATE_ONLY：

def evalClosure = { ->
    myProperty = 'bar'
}
evalClosure.resolveStrategy = Closure.DELEGATE_ONLY
MyClass.metaClass.evaluate = evalClosure

def mc = new MyClass()
mc.evaluate()
println mc.myProperty // prints out "bar" as desired

我更喜欢使用方法 #2 来避免在我的闭包中到处都有“委托”，但我不喜欢为我创建的每个闭包设置解决策略。

我如何告诉 Groovy 默认对所有闭包使用 DELEGATE_ONLY 解析策略？这甚至可能吗？

Answer 1

据我所知，我无法更改默认委派策略，您有两种选择：

1. 将您的脚本拆分为类（这样您就不会在同一范围内拥有脚本级别 myProperty 和类级别 myProperty）

2. 编写一个方法来更改resolveStrategy 并在设置metaClass 时调用它，即：

   def only( Closure c ) {
     c.resolveStrategy = Closure.DELEGATE_ONLY
     c
   }
   
   MyClass.metaClass.evaluate = only { ->
       myProperty = 'bar'
   }