Excel VBA Shell.Namespace 不返回任何内容

Question

我正在尝试使用 Excel VBA 提取 .CAB 文件，但出现以下错误：

运行时错误“91”：对象变量或未设置块变量

当我忘记将 Set 与 Object 一起使用时，我通常会得到这个，但我已经检查过了。

我能找到的所有例子都是这个主题的变体：

Private Function DeCab(vSource, vDest) As Long
    Dim objShell, objFileSource, objFileDest As Object
    Set objShell = CreateObject("Shell.Application")
    Set objFileSource = objShell.Namespace(vSource)
    Set objFileDest = objShell.Namespace(vDest)
    Call objFileDest.MoveHere(objFileSource.Items, 4 Or 16) 'Fails here
    Decab = objFileDest.Items.Count
End Function

Set 行没有失败，但它会将 objFileSource 和 objFileDest 设置为 Nothing，即使我已经确认 vSource 和 vDest 存在。

为了确认它与 .CAB 文件无关，我也尝试过不设置 objFileSource 并在设置后检查 objFileDest 的值。它仍然返回Nothing。为什么会这样？我使用的是 64 位 Windows 7，运行 Office 2010。

Answer 1

您的参数必须作为 Variant 提交，而不是 String

Sub Tester()

    Dim src, dest                      '<< works
    'Dim src As String, dest As String '<< gives the error you see

    src = "D:\temp\test.zip"
    dest = "D:\temp\unzip"

    DeCab src, dest

End Sub

https://msdn.microsoft.com/en-us/library/windows/desktop/bb774085(v=vs.85).aspx

Answer 2

蒂姆的回答是正确的。我也找到了替代方案：

Private Function DeCab(vSource, vDest) As Long
    Dim objShell, objFileSource, objFileDest As Object
    Set objShell = CreateObject("Shell.Application")
    Set objFileSource = objShell.Namespace((vSource)) '<-extra parentheses
    Set objFileDest = objShell.Namespace((vDest)) '<-extra parentheses
    Call objFileDest.MoveHere(objFileSource.Items, 4 Or 16) 'Fails here
    Decab = objFileDest.Items.Count
End Function

当您在 VBA 中将一个对象放在括号中时，它会返回该对象的默认值。显然，objShell.Namespace 无法处理指针。它只能处理字符串文字。如果您传入字符串，将签名更改为以下内容也可以：

Private Function DeCab(ByVal vSource, ByVal vDest) As Long