具有类似条件的 Excel VBA 案例语句未按预期工作

Question

早上好，

我遇到了类似的问题：Case Like doesn't work in VBA

基本上，当我们使用 LIKE 运算符时，我们会得到我们认为应该得到的不同结果。她的似乎只是跳到最后没有结果，但我的使用第一个案例，并且只使用第一个案例，而忽略其余的案例，即使它们不匹配。

我想要的效果是我想选择一个单元格范围，并为范围内的每个单元格循环导出值到具有不同前缀的文本文件，具体取决于单元格列：

    Sub test()
    Dim r As Excel.Range, cell As Excel.Range
    On Error Resume Next
    Set r = Application.InputBox("Select Range", "Select Range", Type:=8)
    On Error GoTo 0
    If r Is Nothing Then Exit Sub

    Open "C:\Users\User_Name\Documents\Macro Results\text.txt" For Output As #1
    For Each cell In r
        Select Case CellVal
            Case cell.Address Like "$A$#"
                Print #1, "Last Name: " + cell.Value + " " + cell.Address
            Case cell.Address Like "$B$#"
                Print #1, "First Name: " + cell.Value + " " + cell.Address
    Case cell.Address Like "$C$#"
                'Do Nothing Print #1, "First Name: " + cell.Value + " " + cell.Address
    Case cell.Address Like "$F$#"
                Print #1, "Email: " + cell.Value + " " + cell.Address
    Case cell.Address Like "$G$#"
                Print #1, "Phone#: " + cell.Value + " " + cell.Address
    Case cell.Address Like "$H$#"
                'Do Nothing 
    Case cell.Address Like "$I$#"
                'Do Nothing 
    Case cell.Address Like "$J$#"
                'Do Nothing 
    Case cell.Address Like "$K$#"
                'Do Nothing 
    Case cell.Address Like "$L$#"
                'Do Nothing 
    Case cell.Address Like "$M$#"
                'Do Nothing 
    Case cell.Address Like "$N$#"
                Print #1, "Token Type: " + cell.Value + " " + cell.Address
    Case cell.Address Like "$O$#"
                Print #1, "Token#:" + cell.Value + " " + cell.Address
            Case Else
        End Select
    Next
    Close
End Sub

我希望输出看起来像：

Last Name: 
First Name: 
Email: 
Phone#: 
Token Type: 
Token#: 

我不想为 like 语句添加每个单独的单元格列，但是在测试宏中，我能够使用这种技术成功区分 A 列和 B 列。它在最终的电子表格中不起作用。

任何帮助或指导将不胜感激。谢谢！

Answer 1

为什么不简单地将您的Case 建立在单元格的.Column 上？无需使用模糊 Like 运算符/等。

Sub test()
    Dim r As Excel.Range, cell As Excel.Range
    On Error Resume Next
    Set r = Application.InputBox("Select Range", "Select Range", Type:=8)
    On Error GoTo 0
    If r Is Nothing Then Exit Sub

    Open "C:\Users\User_Name\Documents\Macro Results\text.txt" For Output As #1
    For Each cell In r
        Select Case cell.Column
            Case 1
                Print #1, "Last Name: " + cell.Value + " " + cell.Address
            Case 2
                Print #1, "First Name: " + cell.Value + " " + cell.Address
            Case 6
                Print #1, "Email: " + cell.Value + " " + cell.Address
            Case 7
                Print #1, "Phone#: " + cell.Value + " " + cell.Address
            Case 14
                Print #1, "Token Type: " + cell.Value + " " + cell.Address
            Case 15
                Print #1, "Token#:" + cell.Value + " " + cell.Address
            Case Else
        End Select
    Next
    Close
End Sub

从 cmets 更新：类型不匹配

类型不匹配源于您使用+ 作为字符串连接器。在 VBA 中，您可以使用 + 或 &。奇怪的是，如果您在处理混合数据类型（整数/长整数、字符串等）时尝试使用+，那么它可能会尝试将其用作数学运算符（加号）。以几种不同的方式避免这种情况：

我的偏好是始终使用& 作为字符串连接符：

 Print #1, "Token#:" & cell.Value & " " + cell.Address

或者将值转换为字符串变量（您已经弄清楚了）。

 Dim v as String
 v = cell.value
 Print #1, "Token#:" + v + " " + cell.Address

另一种选择直接转换为字符串：

 Print #1, "Token#:" + CStr(cell.Value) + " " + cell.Address