通过 VBA 反复添加启用宏的按钮答案

【问题标题】：Repeatedly adding a macro enabled button through VBA通过 VBA 反复添加启用宏的按钮
【发布时间】：2019-02-27 15:59:19
【问题描述】：

尝试创建一个用户可以输入注释的输入框，这些注释将输入到同一个文档中，同时创建一个宏启用“点赞图标”，该宏将包含一个宏，其他成员可以“点赞”想法他们想推广。下面的代码导致按钮在同一个单元格上复制自身。我需要它来应用到下一个可用的单元格。

Sub VBA_Input_Idea_inputbox() 
 Dim MyInp As String
 Dim NextRow As Long

 MyInp = VBA.Interaction.InputBox("Please input idea", "LEARNING 
    REQUEST")
  If MyInp = "" Then Exit Sub
 NextRow = Cells(Rows.Count, 3).End(xlUp).Row + 1
 Range("C" & NextRow).Value = 
 Excel.WorksheetFunction.Proper(MyInp)
 Range("A" & NextRow).Select
 ActiveSheet.Buttons.Add(0.75, 145.5, 42, 24.75).Select
 Selection.OnAction = "Addcount"
  End Sub

【问题讨论】：

尝试在您的代码中使用avoid using activate and select。它会让你更容易得到你想要的
那是加法的事情，你有没有对buttons.add做过调查？当您使用ActiveSheet.Buttons.Add(0.75, 145.5, 42, 24.75).Select 添加时，即每次都在同一个地方：o）。您需要更改这些数字，因此请使用cells(1,2).top 等进行排序。
stackoverflow.com/questions/4559094/…
How to add a button programmatically in VBA next to some sheet cell data?的可能重复
Nathan-您对“如何在 VBA 中以编程方式在某些工作表单元格数据旁边添加按钮？”的建议？发现。感谢您的链接。

标签： excel vba

【解决方案1】：

类似这样的：

Sub VBA_Input_Idea_inputbox()
    Dim MyInp As String
    Dim NextRow As Range, btn

    MyInp = VBA.Interaction.InputBox("Please input idea", "LEARNING REQUEST ")
    If MyInp = "" Then Exit Sub
    With ActiveSheet.Cells(Rows.Count, 3).End(xlUp).Offset(1, 0).EntireRow
       .Cells(3).Value = Application.Proper(MyInp)
       Set btn = ActiveSheet.Buttons.Add(.Cells(1).Left, .Cells(1).Top, _
                                         .Cells(1).Width, .Cells(1).Height)
       btn.OnAction = "Addcount"
    End With
End Sub

【讨论】：