使用 XSL 将 XML 节点替换为新节点

Question

我需要一个 XSL 解决方案来用新节点替换 XML 节点。

假设我有以下现有的 XML 结构：

<root>
    <criteria>
        <criterion>AAA</criterion>
    </criteria>
</root>

我想将一个标准节点替换为：

<criterion>BBB</criterion>
<criterion>CCC</criterion>
<criterion>DDD</criterion>

这样最终的XML结果是：

<root>
    <criteria>
        <criterion>BBB</criterion>
        <criterion>CCC</criterion>
        <criterion>DDD</criterion>
    </criteria>
</root>

我尝试使用 substring-before 和 substring-after 来复制结构的前半部分，然后只复制后半部分（以便在两半之间填充我的新节点），但似乎子字符串函数只能识别节点标签之间的文本，而不是像我想要的那样识别标签本身。 :( :(

还有其他解决方案吗？

Answer 1

XSL 不能替换任何东西。您可以做的最好的事情是复制您想要保留的部分，然后输出您想要更改的部分而不是您不想保留的部分。

---

例子：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
    <xsl:output method="xml" indent="yes"/>

    <!-- This is an identity template - it copies everything
         that doesn't match another template -->
    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

  <!-- This is the "other template". It says to use your BBB-DDD elements
       instead of the AAA element -->
  <xsl:template match="criterion[.='AAA']">
    <xsl:element name="criterion">
      <xsl:text>BBB</xsl:text>
    </xsl:element>
    <xsl:element name="criterion">
      <xsl:text>CCC</xsl:text>
    </xsl:element>
    <xsl:element name="criterion">
      <xsl:text>DDD</xsl:text>
    </xsl:element>
  </xsl:template>
</xsl:stylesheet>

---

模板匹配@* | node() 匹配任何属性或任何其他类型的节点。诀窍是模板匹配具有优先级。您可以将规则视为“更具体的比赛获胜”。 Anything 将比“任何属性或其他节点”更具体。这使得“身份”匹配的优先级很低。

当它被匹配时，它简单地复制它在匹配的属性或节点中找到的任何节点。

您拥有的任何其他模板将具有更高的优先级。无论它们匹配什么，都会有更具体的模板中的代码生效。例如，如果您只是删除了 criterion[.='AAA'] 模板中的所有内容，您会发现您已经完全复制了您的输入，除了“AAA”元素。

Answer 2

这是一个正确的解决方案，可能是最短的解决方案之一：

 <xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="criterion[. = 'AAA']">
  <criterion>BBB</criterion>
  <criterion>CCC</criterion>
  <criterion>DDD</criterion> </xsl:template>
</xsl:stylesheet>

当对提供的 XML 文档应用这种转换时，会产生想要的结果：

<root>
    <criteria>
        <criterion>BBB</criterion>
        <criterion>CCC</criterion>
        <criterion>DDD</criterion>
    </criteria>
</root>

请注意：

1. 身份模板的使用。

2. 身份模板如何被特定模板覆盖——仅适用于criterion元素，其字符串值为'AAA'。

Answer 3

根据不止一种给猫剥皮的一般规则

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml"/>
    <xsl:template match="/">
        <xsl:apply-templates />
    </xsl:template>
    <!--  
        when you capture a node with the text 'AAA'
            emit the BBB, CCC, DDD nodes
     -->
    <xsl:template match="criterion[text() = 'AAA']">
        <xsl:element name="criterion">
            <xsl:text>BBB</xsl:text>
        </xsl:element>
        <xsl:element name="criterion">
            <xsl:text>CCC</xsl:text>
        </xsl:element>
        <xsl:element name="criterion">
            <xsl:text>DDD</xsl:text>
        </xsl:element>
    </xsl:template>
    <!--  identity template  -->
    <xsl:template match="@*|node()">
      <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
    </xsl:template>
</xsl:stylesheet>