【问题标题】:Push value of key-value pair of hash into array将哈希键值对的值推入数组
【发布时间】:2018-11-29 22:06:10
【问题描述】:

我有一个数组,它从一个包含 3 列的 csv 文件中分配值

CSV 文件:

Name,Age,City
Joe,30,NYC
Mary,32,Washington
.
.
.
n number of lines

所以我将它传递给我的 perl 脚本并分配这些变量

($name,$age,$city) = split(",",$_,3);
push @array, "$name,$age,$city";

但是,我在 2 个哈希中有一个键值对,我想将其推送到这个数组中。

这是哈希

%hash  = ('NYC' => NYC, 'Washington' => Virginia, and so on)
%hash2 = ('NYC' => US, 'Washington' => US, 'London' => UK, and so on)

我想在我的数组中再添加 2 列 State 和 Country,使其最终看起来像

Name,Age,City,State,Country
Joe,30,NYC,NY,US
Mary,32,Washington,Virginia,US
.
.
.
n number of lines

我尝试了 switch 语句

 switch($city){
            case "NYC"         {$state = "NY"; $country = "US";
                       push @array, "$name,$age,$city,$state,$country";
                               }
               }

但是没用。

任何帮助表示赞赏

【问题讨论】:

  • 您如何确定它不起作用?哈希的意义何在,您似乎没有使用它们?
  • 您应该 (1) 使用严格和警告,因为您当前正在使用一堆全局变量,这会使您的代码变得复杂和混乱,并且您有未加引号的字符串。 (2) 避免使用 switch/case,因为它是实验性的,并且由于它的使用 smartmatch 会根据情况做出令人困惑的事情,如果你真的想要 switch/case 语法,只需使用 if/elsif 语句或Switch::Plain。
  • @zdim - 你没看错。我以为您只需选择您认为正确的答案即可分配投票。看来我也需要投票。刚刚做到了:)

标签: arrays perl hash switch-statement


【解决方案1】:

首先,您放在数组中的是单个字符串,所有内容都包含在双引号中。这很可能是您的本意,但我想一步一步完成。

push 采用一个列表,因此您可以列出所有要添加的变量,在这种情况下根本不需要引用。要添加“州”和“国家”,只需从您的哈希值中提取键 $city

push @array, $name, $age, $city, $hash{$city}, $hash2{$city};

但是如果这个数组是用来获取更多记录的,那么如何区分它们呢?一种方法是每次都添加一个数组引用,所以

push @array, [ $name, $age, $city, $hash{$city}, $hash2{$city} ];

大括号[ ] 构建一个匿名数组并返回一个对它的引用,它本身可以是一个数组元素,因为它是一个标量。检索单个项目并不是很好,因为您必须对此进行索引,例如 $array[$index]->[0] 的名称(或简写 $array[$index][0])。但是,如果您经常需要所有这些,那么它是完美的:my @data = @{ $array[$index] };

另一种方法是添加一个哈希引用,使用{ },例如

push @array, { name => $name, age => $age, city => $city, 
      state => $hash{$city}, country => $hash2{$city} };

然后您可以将值检索为$array[$index]->{name}(等)。这显然非常适合处理单个组件。

另一种方法是确实为每条记录添加一个字符串;然后在引号下添加哈希值

push @array, "$name,$age,$city,$hash{$city},$hash2{$city}";

因为哈希值可以在双引号字符串中计算。

无论如何,都不需要打开$city——这正是哈希的用途,将值与键相关联,然后可以直接为键检索值。


我想补充一下,如何以更丰富的方式命名这些哈希?

例如

my %state   = (NYC => 'NY', Washington => 'Virginia');            # ...
my %country = (NYC => 'US', Washington => 'US', London => 'UK');  # ...

然后你就更清楚了

push @records, "$name,$age,$city,$state{$city},$country{$city}";

我还更改了数组名称。

关于命名的附注。我使用了一个约定,其中哈希名称是单数的(“state”,而不是“states”),其理由是它指的是单个命名项目,$state{$city}(state-for-city);选择得当的变量名很明显这代表什么。但这不是任何形式的“规则”,也可以使用复数形式(“states”而不是“state”)。

【讨论】:

  • 非常感谢你们。你的两个建议都奏效了。我不知道我可以只使用 $hash{$city}。这解决了我的问题。但是我不知道是否可以为一个键分配两个值。例如 %hash = ( NYC => “NY”,”NAM”, Washington => “Virginia”,”NAM”, London => “UK”,”EMEA”) 然后能够显示区域 NAM,EMEA作为另一列。
  • @user3423407 很高兴它有帮助:)。散列中键的值必须是标量。这意味着一个单值的东西(或适用的表达式),所以它不能是一个列表。但是你可以放一个引用,因为引用 is 是一个标量。例如%h = (NYC => ['NY', 'NAM'], ...) 其中[ ... ] 是一个arrayref,就像我在上面第二行中使用的一样。然后您可以将值提取为:@{$h{NYC}} 以获取两者的列表,或者 $h{NYC}->[0] 用于第一个 (NY) 和 ->[1] 用于第二个。或者你可以使用 hashref,就像上面第三行一样。
  • @user3423407 这是一种构建复杂数据结构的方法,请参阅perldsc。使用复杂数据的另一种主要方式是使用类,它当然提供的不仅仅是数据组织。
  • @user3423407 如果我在评论中倾倒的内容不透明或不清楚,请告诉我!
  • 非常感谢您的建议。我一直在玩这个,它似乎很有魅力。非常感谢您花时间解释还介绍了 perl 数据结构。我很想了解有关使用 perl 解析日志的更多信息,不确定您是否可以向我指出一些好的文档
猜你喜欢
  • 1970-01-01
  • 2019-07-03
  • 1970-01-01
  • 2013-03-22
  • 2019-03-03
  • 1970-01-01
  • 2011-09-01
  • 2016-02-05
  • 1970-01-01
相关资源
最近更新 更多