如何将鼠标位置放在其他图像中找到的图像的一部分？

Question

我正在使用AForge 库在使用this code example 的其他图像中查找（部分）图像。

（以下图片仅供参考）

我正在使用这个 1920x1080 像素的桌面截图：

然后我搜索并找到上面这张图片（55x557 像素）：

但我将两个图像的大小调整为 25%（以获得比较速度），所以当我比较图像时，桌面截图是 480x270 px。剪切后的图像是13x14 px。

使用AForge 库，它返回我在调整大小的桌面屏幕截图中找到（剪切）图像的相对坐标，坐标为x=86, y=200。

现在我需要在我的桌面设置鼠标位置，在 VMWare 图标的中心（更确切地说是在找到的切割图像的中心），这就是我感到困惑的地方，算术运算是什么在那里设置鼠标位置？

我会记住的：

决议：

我的桌面：1920x1080

图片 1：1920x1080

在 Image1 中查找的图像：55x57

调整后的图像 1：480x270

调整大小的图像以在 Image1 中找到：13x14

在 Image1 中找到的已调整大小图像的相对坐标：

x=86，y=200

Answer 1

当你缩小图像时，你会这样做：

intReducePct = 25
ReducedImg1 = ResizeImage(desktopBMP, intReducePct)

' save a restore factor
intFactor = (100 / intReducePct)      ' == 4

' I dont know what the AFOrge search returns, a Point probably
foundPt = Aforge.FindImgInImg(...)

' convert fountPt based on reduction factor (you reduced by 1/4th,
'    so scale up by 4x, basically)
Dim actualPoint As New Point(foundPt.X * intFactor, foundPt.Y * intFactor) 

AForge 返回 x=86, y=200；和 86*4 = 344； 200*4=800 但这是原始图像中的顶部/左侧 (?)，您显然想要找到的图像的中心，因此还要针对原始位图进行调整：

' convert fountPt based on reduction factor + bmpFind size:
Dim actualPoint As New Point((foundPt.X * intFactor) + (bmpFind.Width \ 2),
                             (foundPt.Y * intFactor) + (bmpFind.Height \ 2))

bmpFind 将是缩小前的原始图像。 Option Strict 会坚持一些 CType，但这应该是它的要点。

Answer 2

如果你真的找到了这个位置，并且你真的在使用缩小到 1/4 的整个桌面而不是一个窗口，那么你可以简单地乘回原始比例并像这样移动鼠标：

newPos= new Point(foundX * 4, foundY * 4);
Cursor.Position = newPos;

如果您的 FoundPosition 不是 Middle 而是 TopLeft，您将像这样调整 newPos：

newPos= new Point(foundX * 4 + originalWidth / 2, foundY * 4 + originalHeight / 2);

如果您在窗口中，您还必须在设置鼠标位置之前使用PointToScreen() 函数计算屏幕坐标的相对位置。

Answer 3

我想分享一下我为简化事情而写的这个通用使用方法：

''' <summary>
''' Finds a part of an image inside other image and returns the top-left corner coordinates and it's similarity percent.
''' </summary>
''' <param name="BaseImage">
''' Indicates the base image.
''' </param>
''' <param name="ImageToFind">
''' Indicates the image to find in the base image.
''' </param>
''' <param name="Similarity">
''' Indicates the similarity percentage to compare the images.
''' A value of '100' means identical image. 
''' Note: High percentage values with big images could take several minutes to finish.
''' </param>
''' <returns>AForge.Imaging.TemplateMatch().</returns>
Private Function FindImage(ByVal BaseImage As Bitmap,
                           ByVal ImageToFind As Bitmap,
                           ByVal Similarity As Double) As AForge.Imaging.TemplateMatch()

    Dim SingleSimilarity As Single

    ' Translate the readable similarity percent value to Single value.
    Select Case Similarity

        Case Is < 0.1R, Is > 100.0R ' Value is out of range.
            Throw New Exception(String.Format("Similarity value of '{0}' is out of range, range is from '0.1' to '100.0'",
                                              CStr(Similarity)))

        Case Is = 100.0R ' Identical image comparission.
            SingleSimilarity = 1.0F

        Case Else ' Image comparission with specific similarity.
            SingleSimilarity = Convert.ToSingle(Similarity) / 100.0F

    End Select

    ' Set the similarity threshold to find all matching images with specified similarity.
    Dim tm As New AForge.Imaging.ExhaustiveTemplateMatching(SingleSimilarity)

    ' Return all the found matching images, 
    ' it contains the top-left corner coordinates of each one 
    ' and matchings are sortered by it's similarity percent.
    Return tm.ProcessImage(BaseImage, ImageToFind)

End Function

一个用法示例：

Private Sub Test() Handles MyBase.Shown

    ' A Desktop Screenshot, in 1920x1080 px. resolution.
    Dim DesktopScreenshoot As New Bitmap("C:\Desktop.png")

    ' A cutted piece of the screenshot, in 50x50 px. resolution.
    Dim PartOfDesktopToFind As New Bitmap("C:\PartOfDesktop.png")

    ' Find the part of the image in the desktop, with the specified similarity.
    For Each matching As AForge.Imaging.TemplateMatch In
        FindImage(BaseImage:=DesktopScreenshoot, ImageToFind:=PartOfDesktopToFind, Similarity:=80.5R) ' 80,5% Similarity.

        Dim sb As New System.Text.StringBuilder

        sb.AppendFormat("Top-Left Corner Coordinates: {0}", matching.Rectangle.Location.ToString())
        sb.AppendLine()
        sb.AppendFormat("Similarity Image Percentage: {0}%", (matching.Similarity * 100.0F).ToString("00.00"))

        MessageBox.Show(sb.ToString)

    Next matching

End Sub