如何从 TK 顶层窗口返回值？

Question

我有一个打开 TK 顶层窗口的 TCL 脚本。在这个窗口中，用户可以操作一些小部件（调用其他程序来完成某些工作的按钮、检查按钮等）。当用户完成后，我希望他单击此窗口中的一个按钮，该按钮将导致顶层被破坏并且打开它的过程返回一个值。这是我所拥有的：

proc openWindow {} {
    set w .testwindow
    catch {destroy $w}
    toplevel $w

    <here I setup all the widgets of the window>

    button $w.btn -text "Exit" -command {
        set ret [finishTest]
        puts "returning $ret"
        return $ret
    }

    pack $w.btn
    pack $w
}

proc finishTest {} {
    <here I evaluate the state of the $w widgets>
    if {some condition} {
        destroy $w
        return 0
    } else {
        destroy $w
        return -1
    }
}

当我调用 openWindow 时，窗口显示并正常运行，当我单击退出按钮时，它正确打印“returning: $ret”，但是当我调用 puts [openWindow] 时，它只打印一个新行而没有其他点击按钮后的字符。

我全局定义了 $w 变量，以便我可以在 finishTest 过程中的 openWindow 之外访问它。

感谢您的建议！

Answer 1

回调不能影响局部变量，并且您的 openWindow 目前没有等待回调在返回之前处理。为了让它工作，你必须使用vwait（或tkwait）让事件循环运行直到回调被执行。 （它通过运行一个辅助事件循环来实现这一点，这确实占用了堆栈空间，因此请注意重入问题。）查看下面的标记行（您的 finishTest 未更改）。

proc openWindow {} {
    global ret;                                #########################
    set w .testwindow
    catch {destroy $w}
    toplevel $w

    <here I setup all the widgets of the window>

    button $w.btn -text "Exit" -command {
        set ret [finishTest];                  #########################
    }

    pack $w.btn
    pack $w
    vwait ret;                                 #########################
    puts "returning $ret";                     #########################
    return $ret;                               #########################
}

如果对openWindow 的调用可以从coroutine 内部完成（即，可挂起的堆栈上下文），则可以使用Tcl 8.6 的协程来解决这个混乱。这将使这部分代码看起来更像（再次注意标记的行）：

proc openWindow {} {
    set w .testwindow
    catch {destroy $w}
    toplevel $w

    <here I setup all the widgets of the window>

    button $w.btn -text "Exit" -command [info coroutine];   #########################

    pack $w.btn
    pack $w
    yield;                                                  #########################
    set ret [finishTest];                                   #########################
    puts "returning $ret";                                  #########################
    return $ret;                                            #########################
}