所有用户的成员身份 SHA1 哈希值都不相同答案

【问题标题】：Membership SHA1 hash not the same for all users所有用户的成员身份 SHA1 哈希值都不相同
【发布时间】：2013-06-14 15:08:56
【问题描述】：

我有一个纯文本形式的用户表，并将其迁移到成员资格提供程序。

使用 ColdFusion（当前系统）我设法对一个用户的密码（测试用户）进行哈希处理，并且它完美匹配。但是现在后面的用户不匹配。我做错了什么。

<cfscript>
    theEncoding = "UTF-16LE";
    thePassword = "dtD3v310p3r!";
    base64Salt = "JZjdzUXREM0A7DPI3FV3iQ==";
    theSalt = charsetEncode( binaryDecode(base64Salt, "base64"), theEncoding );
    theHash = hash(theSalt & thePassword, "SHA1", theEncoding);

    // hash always returns hex. convert it to base64 so it matches DNN
    theBase64Hash = binaryEncode(binaryDecode(theHash, "hex"), "base64");
    WriteOutput("<br />theBase64Hash= "& theBase64Hash &"<br/>");
    WriteOutput("DBPassword= 5khDDMmoFtW+j99r/whE/TjyIUo= <br />");


    theEncoding = "UTF-16LE";
    thePassword = "DT!@12";
    base64Salt = "+muo6gAmjvvyy5doTdjyaA==";
    theSalt = charsetEncode( binaryDecode(base64Salt, "base64"), theEncoding );
    theHash = hash(theSalt & thePassword, "SHA1", theEncoding);

    // hash always returns hex. convert it to base64 so it matches DNN
    theBase64Hash = binaryEncode(binaryDecode(theHash, "hex"), "base64");
    WriteOutput("<br />theBase64Hash= "& theBase64Hash &"<br/>");
    WriteOutput("DBPassword= nfcqQBgeAm0Dp1oGZI0O70Y6DvA= <br />");
</cfscript>

第一个工作 100%。但第二个没有。第二个产生的哈希值为86SrPKXW5xywDYoC8MVy0q259sQ=

【问题讨论】：

您使用的盐是否正确？
@MattBusche - 我相信他正在尝试将数据库中的哈希与 ColdFusion 进行匹配。您将在他的代码示例中看到它正在打印生成的 ColdFusion 散列和我认为他从数据库中复制的“DBPassword”散列。第一个匹配，第二个不匹配（我尚未确认）。
是的，两者都来自 HASH 来自 Membership 表。我选择了前 2 名来拉记录。所以我不可能犯了复制错误哈希的错误。

标签： sql-server-2005 coldfusion asp.net-membership coldfusion-9

【解决方案1】：

嗯.. 我认为当两个值连接时可能会出现问题。散列实际上应该使用字节数组，like with the encrypt version，但不幸的是 CF9 的 hash() 函数不支持它 - 只有字符串。（虽然文档很少，但在 CF11 中得到支持）。我不确定是否有针对 CF9 的纯 CF 解决方法。但是，同时您可以直接使用 java：

<cfscript>
    thePassword = "DT!@12";
    base64Salt = "+muo6gAmjvvyy5doTdjyaA==";

    // extract bytes of the salt and password
    saltBytes = binaryDecode(base64Salt, "base64");
    passBytes = charsetDecode(thePassword, "UTF-16LE" );

    // next combine the bytes. note, the returned arrays are immutable, 
    // so we cannot use the standard CF tricks to merge them    
    ArrayUtils = createObject("java", "org.apache.commons.lang.ArrayUtils");
    dataBytes = ArrayUtils.addAll( saltBytes, passBytes );

    // hash binary using java
    MessageDigest = createObject("java", "java.security.MessageDigest").getInstance("SHA-1");
    MessageDigest.update(dataBytes);    
    theBase64Hash = binaryEncode(MessageDigest.digest(), "base64");

    WriteOutput("<br />theBase64Hash= "& theBase64Hash &"<br/>");
    WriteOutput("DBPassword= nfcqQBgeAm0Dp1oGZI0O70Y6DvA= <br />");
</cfscript>

更新：

进一步环顾四周，我认为没有纯 CF 解决方案。 UTF-16LE 编码只是问题的一部分。另一个问题是 DNN 单独解码每个字符串，这可能会产生与将两者解码为单个字符串时不同的字节（参见下面的比较）。它适用于您的第二个密码，这就是最终哈希值不同的原因。由于hash 不接受字节数组，我认为它不是适合这项工作的工具。 MessageDigest 是要走的路。

字节数组比较

           old|   new | 
   1 |     -6 |    -6 | 
   2 |    107 |   107 | 
   3 |    -88 |   -88 | 
   4 |    -22 |   -22 | 
   5 |      0 |     0 | 
   6 |     38 |    38 | 
   7 |   -114 |  -114 | 
   8 |     -5 |    -5 | 
   9 |    -14 |   -14 | 
  10 |    -53 |   -53 | 
  11 |   -105 |  -105 | 
  12 |    104 |   104 | 
  13 |     -3 |    77 | **
  14 |     -1 |   -40 | **
  15 |     68 |   -14 | **
  16 |      0 |   104 | **
  17 |     84 |    68 | **
  18 |      0 |     0 | 
  19 |     33 |    84 | **
  20 |      0 |     0 | 
  21 |     64 |    33 | **
  22 |      0 |     0 | 
  23 |     49 |    64 | **
  24 |      0 |     0 | 
  25 |     50 |    49 | **
  26 |      0 |     0 | 
  27 |        |    50 | **
  28 |        |     0 | **

旧 => charsetDecode(theSalt & thePassword, "UTF-16LE")
新 => ArrayUtils.addAll(saltBytes, passBytes);

【讨论】：