循环范围选择下拉菜单

Question

我想为以下步骤创建一个宏，但我是宏的新手，可以使用您的帮助。

我在名为“TABLE”的表格中从单元格 G11 开始有 10 行的列表，每行都有一个验证下拉列表（TRUE 或 FALSE）。以下是我想做的事情。

1. 在宏启动之前，我希望将它们全部设置为 FALSE。

2. 然后我希望它从单元格 G11 开始并从下拉列表中选择 TRUE。整个工作簿都以此为基础，因此一旦将其设置为 TRUE，就会进行一些计算，然后我想从“SECURITIZATION”页面获取结果并将其粘贴到名为“FINAL”的工作表中。

3. 在此之后我想再次转到“TABLE”表，将单元格 G11 从 TRUE 切换到 FALSE，然后转到单元格 G12 并从下拉列表中选择 TRUE 并粘贴“SECURITIZATION”中的结果在 G11 的结果下方的页面。

我浏览了这个宏，但它从同一个单元格的下拉列表中选择，而不是列表。 VBA Loop Through drop down, copy range

这就是我目前所拥有的

Sub SpitValues()

Dim dvCell As Range 
Dim inputRange As Range 
Dim c As Range 
Dim i As Long 


 'Which cell has data validation
Set dvCell = Worksheets("Sheet1").Range("G11") 
 'Determine where validation comes from
Set inputRange = Evaluate(dvCell.Validation.Formula1) 


i = 1 
 'Begin our loop
Application.ScreenUpdating = False 
For Each c In inputRange 
    dvCell = c.Value 

    Worksheets("SECURITIZATION").Cells(i, "A1").Value = Worksheets("SECURITIZATION").Range("G30").Value 
    i = i + 1 
Next c 
Application.ScreenUpdating = True 

Answer 1

试一试。它基于描述。它需要为您的特定副本进行编辑 |粘贴需求，可以在备注中看到。

Option Explicit

Sub SpitValues()

Dim wsTable As Worksheet
Set wsTable = Worksheets("Table")

Dim wsSecuritization As Worksheet
Set wsSecuritization = Worksheets("Securitization")

Dim wsFinal As Worksheet
Set wsFinal = Worksheets("Final")

With wsTable

    .Range("G11").Resize(10, 1).Value = "FALSE"

    Dim rCell As Range
    For Each rCell In .Range("G11").Resize(10, 1)

        rCell.Value = "TRUE"

        'DoEvents
         Application.Wait Now + TimeValue("0:00:10") 'wait for 10 seconds.

        'adjust this to whatever is need for copy | paste operation
        'I didn't see exact requirements for this so I just copy A1 each time below the last used row in column A
        wsFinal.Range("A" & Rows.Count).End(xlUp).Offset(1).Value = wsSecuritization.Range("A1").Value

        rCell.Value = "FALSE"

    Next

End With


End Sub