【发布时间】:2011-09-04 13:46:08
【问题描述】:
我需要在屏幕上同时移动 3 个不同的影片剪辑。 (从下到上) 不使用像 Caurina 这样的补间类的最佳方法是什么?
感谢您的提示。
【问题讨论】:
-
试试TweenLite:
yourClip.y = stage.stageHeight;TweenLite.to(yourClip,1,{y:0});
标签: actionscript-3
我需要在屏幕上同时移动 3 个不同的影片剪辑。 (从下到上) 不使用像 Caurina 这样的补间类的最佳方法是什么?
感谢您的提示。
【问题讨论】:
yourClip.y = stage.stageHeight;TweenLite.to(yourClip,1,{y:0});
标签: actionscript-3
您可以将事件侦听器添加到侦听Event.ENTER_FRAME 事件的显示对象的父容器。在每个 Event.ENTER_FRAME 事件中,您只需减少显示对象的 y 属性,如下例所示。
package
{
import flash.display.Sprite;
import flash.events.Event;
[SWF(width="600", height="500")]
public class Main extends Sprite
{
private var _squares:Vector.<Square>;
public function Main():void
{
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}// end function
private function init(e:Event = null):void
{
removeEventListener(Event.ADDED_TO_STAGE, init);
_squares = new Vector.<Square>();
var redSquare:Square = new Square(0xFF0000, 100);
redSquare.x = 0;
redSquare.y = 400;
addChild(redSquare);
var greenSquare:Square = new Square(0x00FF00, 100);
greenSquare.x = 300;
greenSquare.y = 300;
addChild(greenSquare);
var blueSquare:Square = new Square(0x0000FF, 100);
blueSquare.x = 500;
blueSquare.y = 100;
addChild(blueSquare);
_squares.push(redSquare, greenSquare, blueSquare);
addEventListener(Event.ENTER_FRAME, onEnterFrame);
}// end function
private function onEnterFrame(e:Event):void
{
for each(var square:Square in _squares)
{
if (square.y > 0) square.y -= 5;
}// end for
}// end function
}// end class
}// end package
import flash.display.Sprite;
internal class Square extends Sprite
{
public function Square(color:uint, size:Number)
{
graphics.beginFill(color);
graphics.drawRect(0, 0, size, size);
graphics.endFill();
}// end function
}// end function
我认为,如果您只是使用 Greensock 的 Tweening platform 来代替,您会让自己的生活更轻松。
【讨论】:
您可以在 Flash IDE 中使用帧和补间为它们制作动画。 您也可以自己以编程方式为它们设置动画。将每个影片剪辑放在屏幕底部,编写一些代码将您的影片剪辑稍微移动到屏幕顶部并定期调用(使用 Timer、EnterFrame 事件侦听器或 setInterval),当所有影片剪辑到达顶部(使用 Timer.stop()、removeEventListener 或 clearInterval)。 我不明白您为什么需要这样做,因为有许多补间库可以为您完成所有这些工作。
【讨论】: