如何使用 DataRow 更新数据库？

Question

首先，我在全局中创建了 DataSet 和 MySQLDataAdapter。然后在 Form_Load 事件中，我像这样查询我的所有表。

        dS = New DataSet
        dA = New MySqlDataAdapter(myCommand)
        Using sqlConn As New MySqlConnection(connStr)
            myCommand = New MySqlCommand("Select ID, DevCompanyName from developer_name_table; Select ID, DevType from development_type_table; Select ID, Mukim from mukim_table; Select ID, Daerah from daerah_table; Select ID, Negeri from negeri_table; Select * from project_record ORDER BY FloatNo desc limit 1", sqlConn)
            sqlConn.Open()
            MsgBox("Connection open.")
            Dim myCB As New MySqlCommandBuilder(dA)

            dA.SelectCommand = myCommand
            dA.UpdateCommand = myCB.GetUpdateCommand
            dA.InsertCommand = myCB.GetInsertCommand
            dA.DeleteCommand = myCB.GetDeleteCommand

            dA.Fill(dS)
            dA.FillSchema(dS, SchemaType.Source)
            dS.Tables(0).TableName = "developer_name_table"
            dS.Tables(1).TableName = "development_type_table"
            dS.Tables(2).TableName = "mukim_table"
            dS.Tables(3).TableName = "daerah_table"
            dS.Tables(4).TableName = "negeri_table"
            dS.Tables(5).TableName = "project_record"
        End Using

在我尝试像这样将新记录添加到数据库之前，一切正常。下面的添加记录代码在按钮单击事件下。首先我检查记录是否存在，然后像这样添加一个新行。

        For Each r As DataRow In dS.Tables("project_record").Rows()
            If r.Item("FloatNo") = TextBox1.Text.Trim() Then
                MsgBox("Project exist. Please recheck.")
                Exit Sub
            End If
        Next
        SecurityAdd() 'This is just to fill None if field are empty.
        Dim row = dS.Tables("project_record").NewRow()
        row.Item("FloatNo") = TextBox1.Text.Trim()
        row.Item("DevCompanyName") = ComboBox1.Text.Trim()
        row.Item("DevType") = ComboBox2.Text.Trim()
        row.Item("LotPt") = TextBox2.Text.Trim()
        row.Item("Mukim") = ComboBox3.Text.Trim()
        row.Item("Daerah") = ComboBox4.Text.Trim()
        row.Item("Negeri") = ComboBox5.Text.Trim()
        row.Item("TempReference") = RichTextBox1.Text.Trim()
        row.Item("PermanentNo") = 0
        row.Item("QuotationNo") = 0
        row.Item("InvoiceNo") = 0
        row.Item("Staff") = loggedUser.ToString() 'Just user ID.
        dS.Tables("project_record").Rows.Add(row)
        dA.Update(dS, "project_record")

更新后，我确定 DataSet 已更新，因为我第二次单击添加记录时，消息框告诉我记录存在。但是当我检查我的数据库时，没有新记录？我在这里做错了什么？

Answer 1

问题是您正在尝试将DataAdapter 配置为在DataSet 中的所有6 个表上工作。如果您查看构建的 INSERT 或 UPDATE 命令，您会发现它们是所有表中所有列的组合。设置DataAdapter 为您完成繁重的工作适用于一张桌子。

我不知道negeri 和其余的翻译成什么，但它看起来只有一个是事务表；其余的，如DevCompanyName 似乎是为项目记录表提供值的域/代码表。

通常，其中一些是根据业务规则固定的，不需要添加/更新的方法。其他人可能需要一种添加新项目的方法，但只是偶尔。手动进行这些更新，以便可以设置 DA 并将其与应用程序所关注的主表一起使用。如果有用于添加 Mukim 等人的表单或选项卡，只需在此处插入并刷新即可。

至少，我会将这些域表存储在一个单独的 DataSet 中，这样它们就不会妨碍它们，但只使用一个，您可以像这样配置它：

Using dbcon As New MySqlConnection(MySQLConnStr)

        dsS = New DataSet
        dbcon.Open()

        ' add table 1 - Mukim
        dsS.Tables.Add("Mukim")
        Using cmd As New MySqlCommand("SELECT DeptCode, Descr FROM Department", dbcon)
            dsS.Tables("Mukim").Load(cmd.ExecuteReader())
            cboColors.DataSource = dsS.Tables("Mukim")
            cboColors.DisplayMember = "Descr"    ' ie "Management"
            cboColors.ValueMember = "DeptCode"   ' eg "MGMT"
        End Using

        ' add table 2 - negeri
        ' this table is fixed - new rows are very rare
        Using cmd As New MySqlCommand("SELECT DeptCode, Descr FROM cDepartment", dbcon)
            Dim dt As New DataTable
            dt.Load(cmd.ExecuteReader)
            cboDept.DataSource = dt
            cboDept.DisplayMember = "Descr"             ' "Sommelier"
            cboDept.ValueMember = "DeptCode"            ' "SOMM"
        End Using

        ' etc

        ' main transaction table - project
        ' do this last
        Dim prjcmd = New MySqlCommand(prjSql, dbcon)
        daSample = New MySqlDataAdapter(prjcmd)

        Dim cb As New MySqlCommandBuilder(daSample)
        daSample.SelectCommand = prjcmd
        daSample.InsertCommand = cb.GetInsertCommand
        ' etc

        dsS.Tables.Add("Project")
        daSample.Fill(dsS.Tables("Project"))
        daSample.FillSchema(dsS.Tables("Project"), SchemaType.Source)
    End Using

代码将这些域/代码表存储在DataSet 中，以供可能更改的那些。它们使用DataReader 填充，而不是适配器。任何已修复的内容（例如“部门”）都会发布到相关的 CBO 并被遗忘。根据每个实际更新的频率，您可以对所有这些都使用此方法，并在它们获得新行时绑定到新表。

代码还使用DataTables 创建为相关CBO 的DataSource。我不确定您的代码在做什么，因为它存储了Combobox.Text。如果我用新条目更新 DataTable，它可以被编码为自动显示。

结果是DataAdapter 知道如何更新主项目表等，并且不会被这些其他表混淆。然后插入几乎就是你所拥有的：

    Dim dr = dsS.Tables("Project").NewRow
    dr("Name") = "My New Row"
    dr("Mukim") = cboMukim.SelectedValue     ' MGMT
    ... etc
    dsS.Tables(1).Rows.Add(dr)

    daSample.Update(dsS.Tables("Project"))
    dsS.Tables("Project").AcceptChanges()

    ' See Notes
    Dim rows = daSample.Fill(dsS.Tables("Project"))       ' refresh
    dsS.Tables("Project").Rows.Remove(dr)

1. 由于现在绑定了 Mukim CBO，请使用 SelectedValue 存储到项目中。
2. DataTable 跟踪哪些行是新的、添加的、删除的等。更新后，使用AcceptChanges 清除这些标志。
3. 在表使用 AI PK 的情况下，新行最初将为 0。如果刷新项目表，您将获得带有 db 提供的 PK 的 新 记录。这意味着“我的新行”将有 2 条记录，一条带有实际 db 提供的 Id，一条为零。删除（而不是删除！）我们添加的新行会消除这种情况。

不清楚第 3 项是否适用。 FloatNo 可能是 PK，在这种情况下，您可以跳过删除。此外，遍历“所有”行以查看是否存在“FloatNo”只会遍历加载的一 (1) 行，因为查询包含LIMTI 1 子句。

并非没有，但您可以通过使用DataGridView 来简化 UI。 Mukim 等人可以是 ComboBox 列，而不是表单上的组合框，以便为您在表中添加新行。您只需要在验证和/或他们点击保存后进行更新。

Answer 2

下面是一个简单的例子来展示使用 datarow 插入数据：

Module *GiveAModuleName*

    Function GetTable() As DataTable

     Dim table As DataTable = New DataTable
     table.Columns.Add("ID", GetType(Integer))
     table.Columns.Add("Name", GetType(String))
     table.Columns.Add("Location", GetType(String))
     table.Columns.Add("D.O.B.", GetType(DateTime))
     table.Rows.Add(1, "Koko", "Sydney", 06/12/1990)
     table.Rows.Add(2, "Fido", "Ottawa", 06/12/1990)
     table.Rows.Add(3, "Alex", "California",06/12/1990)
     table.Rows.Add(4, "Charles", "Malta", 06/12/1990)
     table.Rows.Add(7, "Candy", "Delhi", 06/12/1990)
     Return table
    End Function

    Sub Main()
    Dim table As DataTable = GetTable()
    End Sub

End Module

参考this并重写现有代码以插入数据。