如何为 Net::WebSocket::Server 程序编写客户端程序？

Question

我有一个监听 9000 端口的服务器程序。但是我找不到一种方法来为连接 9000 端口的服务器的服务器编写客户端程序。这是服务器程序的主要部分：

use strict;
use warnings;

use Net::WebSocket::Server;
    
my $port = "9000";
my $msg_count = 0;

print "starting server on $port \n\n";

my $count = 2400;

Net::WebSocket::Server->new(
    listen => $port,
    silence_max => 5,

    tick_period => 300,
    on_tick => sub {
        my ($serv) = @_;    
        print "connections >> " . $serv->connections . "\n";    
        print $_->ip() for( $serv->connections() ); print "\n";
        print $_->port() for( $serv->connections() ); print "\n\n";
        $count++;    
    },

    on_connect => sub {
        my ($serv, $conn) = @_;
        $conn->on(   

        handshake => sub {
                my ($conn, $handshake) = @_;
                my $tmp = $handshake->req->origin;
                print "here ... $tmp \n\n";    
        },

            utf8 => sub {
                my ($conn, $msg) = @_;
                my $IP = $conn->ip();
                my $PORT = $conn->port();
                my $SERVER = $conn->server();
                my $SOCKET = $conn->socket();
                my $str = Dumper $SOCKET;

我搜索了互联网，听起来我可以理解的是以下客户端程序：

use strict;
use warnings;
use IO::Socket::SSL;

my $cl=IO::Socket::SSL->new("http://localhost:9000") or die "error=$!, ssl_error=$SSL_ERROR"; 
if($cl) {
    $cl->connect_SSL or die $@;
    # Something about certificates?
    $cl->syswrite("Command");
    close($cl);
}

但它不起作用。客户端程序产生的错误如下：

Expected 'PeerService' at client2.pl line 5.

我是 Socket 编程的新手，目前了解 Perl 中的 websockets 编程。

注意：我在windows平台上。

我运行了建议的示例代码 https://stackoverflow.com/questions/37318581/simple-perl-websocket-client. 它给出了错误“不能在 C:/Strawberry/perl/site/lib/Protocol/WebSocket/Client.pm 第 103 行使用未定义的值作为子例程引用。” ：

use strict;
use warnings;
use Protocol::WebSocket::Client;

my $client = Protocol::WebSocket::Client->new(url => 'ws://localhost:9000') or die "$!";
my $reply = "Free\n";
# Sends a correct handshake header
$client->connect or die "$!";

# Register on connect handler
$client->on(
    connect => sub {
        $client->write('hi there');
    }
) or die "$!";

# Parses incoming data and on every frame calls on_read
$client->read($reply);
print "$reply\n";

# Sends correct close header
$client->disconnect;

Answer 1

请调查WebSocket Server 和 Client 的以下演示代码 sn-ps。

注意：请不要忘记更改代码以匹配您的服务器来源（IP 地址和端口）

use strict;
use warnings;
use feature 'say';

use Net::WebSocket::Server;

my $origin = 'http://192.168.1.160:8080';  # server origin
my $port = 8080;

$| = 1;

say "Starting server on $port";

Net::WebSocket::Server->new(
    listen => $port,
    tick_period => 60,
    on_tick => sub {
        my ($serv) = @_;
        my $stamp = 'Server time: ' . scalar localtime;
        $_->send_utf8($stamp) for $serv->connections;
    },
    on_connect => sub {
        my ($serv, $conn) = @_;
        $conn->on(
            handshake => sub {
                my ($conn, $handshake) = @_;
                $conn->disconnect() unless $handshake->req->origin eq $origin;
            },
            ready => sub {
                my ($conn) = @_;
                say "Client: connect IP $conn->{ip} PORT $conn->{port}";
                my $msg = 'Connected server time is ' . scalar localtime . "\n";
                $_->send_utf8($msg) for $conn->server->connections;
            },
            utf8 => sub {
                my ($conn, $msg) = @_;
                say "Client message: $conn->{ip} $msg";
                $_->send_utf8('Server reply: ' . $msg)
                        for $conn->server->connections;
                $conn->disconnect() if $msg eq 'exit';
            },
            binary => sub {
                my ($conn, $msg) = @_;
                $_->send_binary($msg) for $conn->server->connections;
            },
            pong => sub {
                my ($conn, $msg) = @_;
                $_->send_utf8($msg) for $conn->server->connections;
            },
            disconnect => sub {
                my ($conn, $code, $reason) = @_;
                say "Client: disconnect IP $conn->{ip} PORT $conn->{port}";
            },
        );
    },
)->start;

客户

use strict;
use warnings;
use feature 'say';

use IO::Async::Loop;
use Net::Async::WebSocket::Client;

my $HOST = '192.168.1.160';
my $PORT = 8080;

my $loop = IO::Async::Loop->new;

my $client = Net::Async::WebSocket::Client->new(
   on_text_frame => sub {
      my ( $self, $frame ) = @_;
      say $frame;
   },
);

my $input = IO::Async::Stream->new_for_stdin(
    on_read => sub {
        my ( $self, $buffref, $eof ) = @_;

        my $msg;

        $msg = $1 while $$buffref =~ s/^(.*)\n//;

        $client->send_text_frame( $msg );

        $loop->loop_stop if $msg eq 'exit';

        return 0;
    },
);

$loop->add( $client );
$loop->add( $input  );

$client->connect(
   url => "ws://$HOST:$PORT/"
)->then( sub {
    say 'Successfully connected to server';
    $client->send_text_frame( scalar localtime );
})->get;

$loop->run;

say 'Bye, until next time';

exit 0;

参考资料：

• Net::WebSocket::Server
• Net::Async::WebSocket::Client
• IO::Async::Loop