是否可以创建 MakeBoxesStop 包装器？

Question

输出表达式通过MakeBoxes传递is known，将图形表达式转换为前端用来表示图形的框语言（当$Output具有默认选项FormatType->StandardForm时）。例如，如果我们评估：

HoldComplete[Graphics[Disk[]]]

我们得到一个由HoldComplete包裹的磁盘：

这是因为HoldComplete 不会阻止MakeBoxes 将其内容转换为排版表达式：

In[4]:= MakeBoxes@HoldComplete[Graphics[Disk[]]]
Out[4]= RowBox[{"HoldComplete", "[", GraphicsBox[DiskBox[{0, 0}]], "]"}]

所以我的问题是：是否可以对MakeBoxes 进行一些额外的定义，这样使用头部MakeBoxesStop 包装任何表达式将阻止MakeBoxes 将此表达式转换为排版形式？在这种情况下，表达式在输出中应该与任何其他表达式一样，其中没有与符号关联的规则；在上述情况下：

附：请不要建议使用InputForm，因为I am not satisfied with its default behavior。

Answer 1

这个函数似乎可以做到：

Clear[MakeBoxesStop];
MakeBoxesStop /: MakeBoxes[MakeBoxesStop[expr_], form_] :=
  Module[{heldHeads = 
     Join @@ Cases[expr,s_Symbol[___] :> HoldComplete[s], {0, Infinity}, 
      Heads -> True], 
    modified, direct,  tempContext = ToString[Unique[]] <> "`"},
   Block[{$ContextPath = $ContextPath, $Packages  = $Packages},
     BeginPackage[tempContext];
       modified = 
        Join @@ Map[
          Function[head,
             ToExpression[ToLowerCase[ToString[Unevaluated[head]]],InputForm, HoldComplete],     
             HoldAllComplete], 
          heldHeads];
     EndPackage[];
     With[{newexpr = 
       expr /. (List @@ Thread[HoldPattern /@ heldHeads -> modified, HoldComplete])},
       With[{result = 
        MakeBoxes[newexpr, form] /. 
           Thread[Rule @@ 
              Map[List @@ 
                 Map[Function[head, ToString[Unevaluated[head]], HoldAllComplete], #] &,
                 {modified , heldHeads}]]
            },
            Remove @@ Names[tempContext <> "*"];
            result]]]];

它不会赢得优雅的比赛，并且可能不是很干净，但它似乎可以满足您的要求：

In[270]:= MakeBoxesStop[Graphics[Disk[]]]

Out[270]= Graphics[Disk[List[0, 0]]]

如果您不希望 MakeBoxesStop 中的表达式求值，请在正文中添加适当的属性和 Unevaluated 包装器。

编辑

以下简单的制盒函数基于here发布的 Mathematica 解析器：

Clear[toBoxes];
toBoxes[expr_] :=
  First[parse[tokenize[ToString@FullForm[expr]]] //. {
    head_String[elem_] :>    RowBox[{head, "[", elem, "]"}], 
    head_String[elems___] :>  RowBox[{head, "[", RowBox[Riffle[{elems}, ","]], "]"}]}]

那么，我们需要：

Clear[MakeBoxesStopAlt];
MakeBoxesStopAlt /: MakeBoxes[MakeBoxesStopAlt[expr_], form_] :=  toBoxes[expr]

例如：

In[327]:= MakeBoxesStopAlt[Graphics[Disk[]]]

Out[327]= Graphics[Disk[List[0, 0]]]