如果完成任何操作（在 Delphi 中），如何设置变量？

Question

我需要在 Delphi 2009 中以某种方式实现这一点：

用户点击按钮 2。如果用户的最后一个操作是点击按钮 1，那么我想做一件事，但如果用户的最后一个操作是别的，我想做另一件事。

显然，我设置了一个布尔变量：UserClickedOnButton1，并在单击按钮 1 时将其设置为 true，然后在按钮 2 的 OnButtonClick 事件中测试该变量。

我的问题是，当用户在点击按钮 2 之前执行任何其他操作（例如，鼠标按下、按键、箭头键、切换到另一个程序或其他任何操作）时，如何将其设置为 false。

...或者有没有我忽略的更简单的方法。

Answer 1

下面的代码似乎可以工作 (D7)，但请根据您的具体情况检查。

type
  TButton = class(StdCtrls.TButton)
  private
    FClickedLast: Boolean;
    FNextButton: TButton;
  protected
    procedure WndProc(var Message: TMessage); override;
  public
    procedure Click; override;
    property ClickedLast: Boolean read FClickedLast write FClickedLast;
    property NextButton: TButton write FNextButton;
  end;

  TForm1 = class(TForm)

...

procedure TForm1.FormCreate(Sender: TObject);
begin
  Button1.NextButton := Button2;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  if Button1.ClickedLast then
    Caption := Caption + ' +'
  else
    Caption := Caption + ' -';
  Button1.ClickedLast := False;
end;

{ TButton }

procedure TButton.Click;
begin
  inherited Click;
  if (FNextButton <> nil) and Focused then
    FClickedLast := True;
end;

procedure TButton.WndProc(var Message: TMessage);
begin
  if (FNextButton <> nil) and not (csDestroying in ComponentState) then
    case Message.Msg of
      CM_CANCELMODE,
      WM_KEYFIRST..WM_KEYLAST:
        FClickedLast := False;
      WM_KILLFOCUS:
        if TWMKillFocus(Message).FocusedWnd <> FNextButton.Handle then
          FClickedLast := False;
    end;
  inherited WndProc(Message);
end;

解释：

• CM_CANCELMODE 处理鼠标在任何地方的点击，不会导致焦点改变，
• WM_KEY* 处理所有关键事件，但也切换到另一个应用程序（有一个 WM_SYSKEYDOWN，否则 WM_KILLFOCUS 负责），
• WM_KILLFOCUS 处理其他所有事情。

Answer 2

根据我的想法；除非您愿意用逻辑去跟踪所有（或至少所有可能不需要的）事件，否则这实际上是不可能的。

按键（Tab？）仍然可以有效地移动到下一个按钮并单击它；一个鼠标按下事件，如果它在第二个按钮上显然是好的，否则不是。在执行一大堆逻辑以减慢应用程序中的每个 keypress/mousedown/lostfocus 事件之前，您可能需要检查“第一个按钮是否被单击”。

一个想法可能是使用计时器，但这并不妨碍用户“快速”做其他事情。

Edt1：如果所有其他“非法”操作实际上都在做某事，那么第一个按钮上的 lostfocus 事件可能是一个开始？