Delphi DX10.4 E2064代码无法编译

Question

我不是一个 Delphi 程序员，我很乐意做 C++Builder 编程，delphi 不是我的语言。我有一些用 Delphi 编写的组件，它们在 10.3 中编译良好，但在 10.4 中确实出现错误，我可以看到问题的原因，但我不知道如何修复它。请帮我解决它。

procedure CopyInterlacedRGB8(const Pass: Byte; Src, Dest, Trans, Extra: pChar)

    Dest^ := Char(fOwner.GammaTable[pByte(Longint(Src) + 2)^]); inc(Dest);  // changed these two, but I have no clue what I'm doing lul
    Dest^ := Char(fOwner.GammaTable[pByte(Longint(Src) + 1)^]); inc(Dest);
    Byte(Dest^) := fOwner.GammaTable[pByte(Longint(Src)    )^]; inc(Dest);  // ERROR here

我在这里看到的方式，正如我在 C++ 中所理解的那样，有一个字节正在初始化，并且正在被分配。类似于 char('a') = 5;但是我可以看到代码最初想要做什么，将一些东西分配给Dest的地址。

我应该如何改变这些东西才能正常工作？？

Answer 1

你没有给出GammaTable的声明。我创建了一个看起来合适的。我没有在这里初始化它，但它应该在你的代码中。如果你的声明不同，可能我的代码需要修改。

var
    GammaTable : array [Byte] of Byte;

procedure CopyInterlacedRGB8(const Pass: Byte; Src, Dest, Trans, Extra: pChar);
var
    BDest : PByte;
begin
    BDest  := PByte(Dest);
    BDest^ := GammaTable[PByte(UIntPtr(Src) + 2)^]; Inc(BDest);
    BDest^ := GammaTable[PByte(UIntPtr(Src) + 1)^]; Inc(BDest);
    BDest^ := GammaTable[PByte(UIntPtr(Src)    )^]; Inc(BDest);
end;

我没有更改函数的参数类型，但可以肯定 Src 和 Dst 应该是 PByte 而不是 PChar。无论如何，我编写的代码将同样有效，只要它包含所需的源表和目标表。

我引入了BDest 变量以使代码更具可读性。

注意如果Src被声明为PByte和{$POINTERMATH ON}，那么代码可以简化：

PByte(UIntPtr(Src) + 2)^

变成

Src[2];

所以程序可以这样改写：

{$POINTERMATH ON}
procedure CopyInterlacedRGB8_(const Pass: Byte; Src, Dest : PByte; Trans, Extra: pChar);
begin
    Dest[0] := GammaTable[Src[2]];
    Dest[1] := GammaTable[Src[1]];
    Dest[2] := GammaTable[Src[0]];
end;

更具可读性，不是吗？