StrToInt 有 ansi 版本吗？

Question

StrToInt 似乎没有 Ansi 重载。这是正确的吗？或者，也许我错过了一些东西。 StrToInt 坚持将我的 ansistrings 转换为字符串。

Answer 1

你是对的。 StrToInt 没有 ANSI 版本。找到标准函数的 ANSI 版本的地方是 AnsiStrings 单元，那里什么都没有。

要么编写自己的函数来完成这项工作，要么接受使用StrToInt 所需的转换。

编写自己的函数并不难。它可能看起来像这样：

uses 
  SysConst; // for SInvalidInteger
....
{$OVERFLOWCHECKS OFF}
{$RANGECHECKS OFF}
function AnsiStrToInt(const s: AnsiString): Integer;

  procedure Error;
  begin
    raise EConvertError.CreateResFmt(@SInvalidInteger, [s]);
  end;

var
  Index, Len, Digit: Integer;
  Negative: Boolean;
begin
  Index := 1;
  Result := 0;
  Negative := False;
  Len := Length(s);
  while (Index <= Len) and (s[Index] = ' ') do
    inc(Index);
  if Index > Len then
    Error;
  case s[Index] of
  '-','+':
    begin
      Negative := s[Index] = '-';
      inc(Index);
      if Index > Len then
        Error;
    end;
  end;
  while Index <= Len do
  begin
    Digit := ord(s[Index]) - ord('0');
    if (Digit < 0) or (Digit > 9) then
      Error;
    Result := Result * 10 + Digit;
    if Result < 0 then
      Error;
    inc(Index);
  end;
  if Negative then
    Result := -Result;
end;

这是StrToInt 中的精简版。它不处理十六进制，并且对错误更加严格。在使用此代码之前，我想测试这是否真的是您的瓶颈。

非常有趣的是，这段基于 RTL 源代码的代码无法返回 low(Integer)。修复它并不难，但它会使代码更复杂。

Answer 2

代码实际上很简单（不支持十六进制字符串，但你不需要它们）：

function AnsiStrToInt(const S: RawByteString): Integer;
var
  P: PByte;
  Negative: Boolean;
  Digit: Integer;

begin
  P:= Pointer(S);
// skip leading spaces
  while (P^ = Ord(' ')) do Inc(P);
  Negative:= False;
  if (P^ = Ord('-')) then begin
    Negative:= True;
    Inc(P);
  end
  else if (P^ = Ord('+')) then Inc(P);

  if P^ = 0 then
    raise Exception.Create('No data');

  Result:= 0;
  repeat
    if Cardinal(Result) > Cardinal(High(Result) div 10) then
      raise Exception.Create('Integer overflow');
    Digit:= P^ - Ord('0');
    if (Digit < 0) or (Digit > 9) then
      raise Exception.Create('Invalid char');
    Result:= Result * 10 + Digit;
    if (Result < 0) then begin
      if not Negative or (Cardinal(Result) <> Cardinal(Low(Result))) then
        raise Exception.Create('Integer overflow');
    end;
    Inc(P);
  until (P^ = 0);
  if Negative then Result:= -Result;
end;

Answer 3

我遵循了这个提示：

How to convert AnsiString to UnicodeString in Delphi XE4

例子：

var
  a : AnsiString;
  b : String;
  c : Integer;
begin
  a := '123';
  b := String(a);
  c := StrToInt(b);