Emacs中当前段落的拆分行

Question

我想在 Emacs 中添加一个函数（para2lines），通过它我可以将当​​前段落拆分为句子并在单独的缓冲区中逐行打印它们。以下是 Racket/Scheme 中的代码：

(define (p2l paraString)
  (define lst (string-split paraString ". "))
  (for ((i lst))
    (displayln i)))

测试：

(p2l "This is a test. For checking only. Only three lines.")

输出：

This is a test
For checking only
Only three lines.

在 Emacs Lisp 中，我可以管理以下代码：

(defun pl (ss)
  (interactive)
  (let ((lst (split-string (ss))))
    (while lst
      (print (pop lst)))))

但我不知道如何从当前位置的段落中获取文本。如何更正此功能？

编辑：基本上，我想将其作为单独的行阅读，但想将其保存为段落。

Answer 1

以下示例可能对您有所帮助。它会将您转换为当前段落（即光标所在的位置），而不是转换为新缓冲区。如果这是您需要的，您可以修改它以将字符串传递给您的函数。

(defun p2l ()
  "Format current paragraph into single lines."
  (interactive "*")
  (save-excursion
    (forward-paragraph)
    (let ((foo (point)))
      (backward-paragraph)
      (replace-regexp "\n" " " nil (1+ (point)) foo)
      (backward-paragraph)
      (replace-regexp "\\. ?" ".\n" nil (point) foo))))

Answer 2

我只会运行 Emacs 命令或编写一个宏来将段落转换为单句行，但也许您真的只是想将包装的段落作为行来阅读，因此需要 Emacs 命令。

这里会抓取当前段落，插入一个新缓冲区*Lines*，然后将句子转换为行。

(defun para-lines ()
  "Split sentences of paragraph to lines in new buffer."
  (interactive)
  ;; Move the paragraph to a new buffer.
  (let ((b (generate-new-buffer "*Lines*")))
    (with-output-to-temp-buffer b
      (let ((beg (save-excursion (forward-paragraph -1) (point)))
            (end (save-excursion (forward-paragraph +1) (point))))
        (princ (buffer-substring-no-properties beg end))))
    ;; Switch to new buffer
    (with-current-buffer b
      ;; Since the name starts with "*", shut off Help Mode
      (fundamental-mode)
      ;; Make sure buffer is writable
      (setq buffer-read-only nil)
      ;; From the start of the buffer
      (goto-char (point-min))
      ;; While not at the end of the buffer
      (while (< (point) (point-max))
        (forward-sentence 1)
        ;; Delete spaces between sentences before making new new line
        (delete-horizontal-space)
        ;; Don't add a new line, if already at the end of the line
        (unless (= (line-end-position) (point))
            (newline))))))

要避免使用forward-sentence，而只使用正则表达式，请使用re-search-forward。例如，匹配分号和句点。

(defun para-lines ()
  "Split sentences of paragraph to lines in new buffer."
  (interactive)
  ;; Move the paragraph to a new buffer.
  (let ((b (generate-new-buffer "*Lines*")))
    (with-output-to-temp-buffer b
      (let ((beg (save-excursion (forward-paragraph -1) (point)))
            (end (save-excursion (forward-paragraph +1) (point))))
        (princ (buffer-substring-no-properties beg end))))
    ;; Switch to new buffer
    (with-current-buffer b
      ;; Since the name starts with "*", shut off Help Mode
      (fundamental-mode)
      ;; Make sure buffer is writable
      (setq buffer-read-only nil)
      ;; From the start of the buffer
      (goto-char (point-min))
      ;; While not at the end of the buffer
      (while (< (point) (point-max))
        (re-search-forward "[.;]\\s-+" nil t)
        ;; Delete spaces between sentences before making new new line
        (delete-horizontal-space)
        ;; Don't add a new line, if already at the end of the line
        (unless (= (line-end-position) (point))
            (newline))))))