如何改变emacs在一个单词上移动的方式？

Question

我是一名初级 emacser 。我想知道如何改变·emacs·识别单词的方式。

例如，我在行尾：(font-spec :family "Microsoft YaHei" :size 13)))，现在M-b 向后移动一个单词：

（使用符号| 标记插入符号位置）

emacs：(font-spec :family "Microsoft YaHei" :size |13)))
sublime：(font-spec :family "Microsoft YaHei" :size 13|)))

M-bagian

emacs：(font-spec :family "Microsoft YaHei" :|size 13)))
sublime：(font-spec :family "Microsoft YaHei" :size |13)))

M-b几次

emacs:(font-spec :family "Microsoft YaHei" |:size 13)))
sublime:(font-spec :family "Microsoft YaHei" |:size 13)))

M-bagian

emacs：(font-spec :family "Microsoft |YaHei" :size 13)))
sublime：(font-spec :family "Microsoft YaHei|" :size 13)))

M-b多次

emacs：(font-spec :|family "Microsoft YaHei" :size 13)))
sublime：(font-spec :|family "Microsoft YaHei" :size 13)))

M-bagian

emacs：(font-|spec :family "Microsoft YaHei" :size 13)))
sublime：(font-spec |:family "Microsoft YaHei" :size 13)))

emacs 一个字的移动方式太奇怪了，无法适应它。我更喜欢sublime的方式。我想知道如何改变emacs在word上移动的方式。thx

Answer 1

Emacs 使用语法表，每个字符都属于一个指定的语法类。语法表可能因缓冲区而异，通常根据使用的主要模式的要求而定。

见 C-hig (elisp) Syntax Tables RET

forward-word 和 backward-word 查找“单词”语法的下一个/上一个字符，然后跳过所有后续连续的“单词”语法字符。

我不知道 Sublime 使用什么规则，也无法从您的示例中确定这一点，但是也许这样的东西会更符合您的喜好？

(defun my-backward-word-or-other ()
  "Move over the preceding word or non-word characters."
  (interactive)
  (unless (bobp)
    (if (eq ?w (char-syntax (char-before)))
        (backward-word)
      (skip-syntax-backward "^w"))))

(defun my-forward-word-or-other ()
  "Move over the following word or non-word characters."
  (interactive)
  (unless (eobp)
    (if (eq ?w (char-syntax (char-after)))
        (forward-word)
      (skip-syntax-forward "^w"))))

(global-set-key [remap forward-word] 'my-forward-word-or-other)
(global-set-key [remap backward-word] 'my-backward-word-or-other)