如何在emacs中找到TAGS文件中的文件

Question

我已经使用 ctags 为目录中的 *.h 和 *.cpp 文件生成了 TAGS 文件。 如何在 TAGS 文件中找到文件。

假设我已经为文件 one.h two.h three.h 生成了 TAGS 文件。查找文件 one.h、two.h、three.h 而不是这些文件中的标签的命令是什么。

Answer 1

假设您只是想知道如何使用 TAGS 文件...

使用以下命令加载 TAGS 文件：
M-x visit-tags-table RET TAGS 文件或父目录 RET

然后你可以使用它：

• M-.（即find-tag）
• M-x tags-search RET 模式 RET
  （用 M-, 移动到每个连续的匹配）
• M-x tags-apropos RET 模式 RET
• M-x tags-query-replace RET 模式 RET 替换 RET

这些是默认值。自然有可用的增强功能：
http://www.emacswiki.org/emacs/EmacsTags

我个人使用etags-select（您可以通过ELPA获得），并且我将M-.绑定到etags-select-find-tag。

Answer 2

这是我几年前写的，不过我还没有时间发布它……享受吧！

函数tags-extra-find-file 将允许您访问当前标签表中的文件，并完成文件名完成。如果您有许多源文件分布在大量目录中，这是完美的。 （老实说，我每天至少用一百次……）

(defun tags-extra-get-all-tags-files ()
  "Return all, fully qualified, file names."
  (save-excursion
    (let ((first-time t))
      (while (visit-tags-table-buffer (not first-time))
        (setq first-time nil)
        (setq res
              (append res (mapcar 'expand-file-name (tags-table-files)))))))
  res))


(defun tags-extra-find-file (name)
  "Edit file named NAME that is part of the current tags table.
The file name should not include parts of the path."
  (interactive
   (list
    (completing-read "Name of file: "
                     ;; Make an a-list of all files without path.
                     (mapcar
                      (lambda (file)
                        (cons (file-name-nondirectory file) nil))
                      (tags-extra-get-all-tags-files)))))
  (let ((files (tags-extra-get-all-tags-files))
        (done nil)
        (name-re (concat "^" (regexp-quote name) "$")))
    (while (and (not done)
                files)
      (let ((case-fold-search t))
        (if (string-match name-re (file-name-nondirectory (car files)))
            (setq done t)
          (setq files (cdr files)))))
    (if files
        (find-file (car files))
      (error "File not found in the tags table."))))

Answer 3

这样的？它可能并不完全健壮。

(defun visit-tags-table-and-files (file)                                        
  "Run `visit-tags-table FILE', then visit all the referenced files."           
  (interactive "fTags file: ")                                                  
  (visit-tags-table file)                                                       
  (save-excursion                                                               
    (set-buffer (get-file-buffer tags-file-name))                               
    (mapc #'find-file (tags-table-files)) ) )

Answer 4

此更正适用于 emacs 26.3。带有旧的 etag，M-。将接受一个文件名，例如 Setup.cpp，并访问 etags 找到的文件。在许多目录中有很多文件非常方便。无需记住文件所在的目录即可访问它。我很惊讶这不是一个开箱即用的功能！

 (defun tags-extra-get-all-tags-files ()
  "Return all, fully qualified, file names."
  (setq res nil)
  (save-excursion
    (let ((first-time t))
      (while (visit-tags-table-buffer (not first-time))
        (setq first-time nil)
        (setq res
              (append res (mapcar 'expand-file-name (tags-table-files)))))))
  res)

Answer 5

感谢@Lindydancer 的回答和emacswiki ido。 emacswiki 版本只支持一个标签文件。结合它们，我可以跳转到所有 TAG 文件中的任何文件。小资接近崇高文本的goto任何东西。

这里是代码。

;;; using ido find file in tag files
(defun tags-extra-get-all-tags-files ()
  "Return all, fully qualified, file names."
  (save-excursion
    (let ((first-time t)
          (res nil))
      (while (visit-tags-table-buffer (not first-time))
        (setq first-time nil)
        (setq res
              (append res (mapcar 'expand-file-name (tags-table-files)))))
      res)))

(defun ido-find-file-in-tag-files ()
  (interactive)
  (find-file
   (expand-file-name
    (ido-completing-read
     "Files: " (tags-extra-get-all-tags-files) nil t))))