Haskell 中类型的模式匹配

Question

假设我有一个类型，其中包含定义为的各种对象的坐标：

   type Point = (Int, Int)

   data Object = A Point
               | B Point
               | C Point

我想创建一个函数来检查对象的重叠，就像这样

   checkOverlap:: Object -> Point -> Bool

我只想定义一个适用于所有对象的函数，而不必指定“checkOverlap (A point) (x,y)”、“checkOverlap (B point) (x,y)”等。

我已经用谷歌搜索了这个问题，但我能找到的唯一解决方案是添加一个中间类型，该类型将收集所有不同的对象，以便您可以对该类型进行模式匹配。然而，由于这是一个家庭作业，我不允许修改大块代码来适应这种新类型。

还有其他方法吗？甚至可能没有模式匹配。不得不多次复制同一个函数似乎是糟糕的编程。

Answer 1

如果允许更改Object 的定义，则可以使用记录语法：

type Point = (Int, Int)

data Object = A { getPoint :: Point, ... }
            | B { getPoint :: Point, ... }
            | C { getPoint :: Point, ... }

checkOverlap :: Object -> Point -> Bool
checkOverlap obj pt = doSomething (getPoint obj) pt

如果您不允许更改定义并且提取点是一项常见任务，您可以简单地添加getPoint 作为附加功能。如果不想多次写getPoint，可以使用case：

getPoint :: Object -> Point
getPoint obj = case obj of 
                 A pt -> pt
                 B pt -> pt
                 C pt -> pt

如果您不想要附加功能，但仍只想要一个版本的checkOverlap，您可以将case 移动到checkOverlap：

checkOverlap :: Object -> Point -> Bool
checkOverlap obj pt = let opt = case obj of {A a -> a; B b -> b; C c -> c} 
                      in -- use opt and pt

Answer 2

考虑更改您的对象类型定义：

data ObjTy = A | B | C

data Object = Obj ObjTy Point

checkOverlap:: Object -> Point -> Bool
checkOverlap (Obj _ (x,y)) (u,v) = ...

Answer 3

在我的评论中，这是一种使用类型类的方法：

type Point = (Int, Int)
data Obj = A Point | B Point | C Point


class HasPoint p where
    point :: p -> Point


instance HasPoint (Obj) where
    point (A p) = p
    point (B p) = p
    point (C p) = p


checkOverlap :: (HasPoint ob) => ob -> Point -> Bool
checkOverlap ob otherPoint =
    undefined
      where
          myPoint = point ob

somethingA = checkOverlap (A (1,1)) (1,1)
somethingB = checkOverlap (B (1,1)) (1,1)