FParsec 在可选解析器上失败

Question

我目前正在学习 FParsec 库，但遇到了一个问题。当我想解析一个可选字符串并在之后继续正常解析时，FParsec 将在可选解析器上返回一个致命错误，而不是像我预期的那样返回None。下面的工作代码示例说明了我的观点：

open System
open FParsec

type AccountEntity = 
    | Default 
    | Entity of string

let pEntity =
    let isEntityFirstChar c = isLetter c
    let isEntityChar c = isLetter c || isDigit c
    (many1Satisfy2L isEntityFirstChar isEntityChar "entity") .>> skipString "/"

let pOptEntity =
     opt pEntity
     |>> (fun optEntity -> 
              match optEntity with 
              | Some entity -> Entity entity 
              | None -> Default)

[<EntryPoint>]
let main argv = 
    printfn "%A" (run pOptEntity "test/account:subaccount") //works
    printfn "%A" (run pOptEntity "account:subaccount") //crashes
    Console.ReadLine() |> ignore
    0 // return an integer exit code

我期望pOptEntity 在未提供实体时返回Default 实体的行为。但是，相反，我收到以下错误：

Failure:
Error in Ln: 1 Col: 8
account:subaccount
       ^
Expecting: '/'

opt 不应该提供我所描述的行为并继续正常解析帐户字符串，还是我以不正确的方式处理这个问题？我查看了attempt，但是，我无法提供我想要的默认实体行为。

非常感谢您的帮助，谢谢。

Answer 1

opt combinator 遵循与<|> 相同的规则；如果您查看<|> documentation，它提到如果第一个解析器失败没有更改解析器状态，则会尝试第二个解析器。 http://www.quanttec.com/fparsec/users-guide/parsing-alternatives.html 更详细。

这里，.>>? combinator 是您要在 pEntity 解析器中使用的内容。将.>> 替换为.>>?，您将拥有一个pEntity 解析器，如果它后面没有/，它将回到它尝试的开头而不是消耗输入。这将允许opt 组合器按设计运行。

P.S.我对此进行了测试，它确实有效。将.>> 替换为pEntity 中的.>>?，然后运行您的代码会产生以下输出：

Success: Entity "test"
Success: Default