CMake：$<CONFIG:cfg_list> 或 $<IN_LIST:str,list> 的正确语法是什么？

Question

使用 CMake 版本 3.20.1，我正在做一些我认为相对简单的事情：验证 cfg pass via -DCMAKE_BUILD_TYPE=<cfg> 的值是有效配置。

参考CMake generator expressions 文档，$<CONFIG:cfgs> 似乎是$<IN_LIST:string,list> 的特殊情况，其中字符串为${CMAKE_CONFIGURATION_TYPES}。我得到的 CMake 运行时错误强化了这一点，并告诉我我遗漏了一些东西。

我期望的工作是这样的：

    set( CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Build Configurations" FORCE )
    
    if( NOT $<CONFIG:${CMAKE_CONFIGURATION_TYPES}> )
      # Handle_the_bad_value()
    endif()

当从命令行调用 cmake .. -DCMAKE_BUILD_TYPE=Debug 时，出现以下错误：

CMake Error at CMakeLists.txt:45 (if):
  if given arguments:

    "NOT" "\$<CONFIG:Debug" "Release>"

  Unknown arguments specified    

更换

$<CONFIG:<cfg_list>

与任一：

$<IN_LIST:${CMAKE_BUILD_TYPE},${CMAKE_CONFIGURATION_TYPES}>

或

$<IN_LIST:"Debug","Debug;Release">

给了我以下信息：

CMake Error at CMakeLists.txt:43 (if):
  if given arguments:

    "NOT" "\$<IN_LIST:Debug,Debug" "Release>"

  Unknown arguments specified

在尝试 $<IN_LIST:str,list> 之前，我已经对原始语法进行了各种更改，但是由于我无法使 IN_LIST 语法正常工作，我觉得有一些基本的东西我错了m 也未能从文档中掌握。

---

随后的实验，使用：

    if( NOT ${CMAKE_BUILD_TYPE} IN_LIST ${CMAKE_CONFIGURATION_TYPES} )

产量：

CMake Error at CMakeLists.txt:43 (if):
  if given arguments:

    "NOT" "Debug" "IN_LIST" "Debug" "Release"

  Unknown arguments specified

所以我尝试了蛮力：

if( NOT ( "Debug" IN_LIST "Debug;Release" ) )

它的计算结果不正确，因为它在列表中没有找到“Debug”，所以它在 if 语句中输入代码。最后的尝试：

    if( NOT ( CMAKE_BUILD_TYPE IN_LIST CMAKE_CONFIGURATION_TYPES ) )

是否按预期工作。注意：NOT 应该应用于括号内的 表达式。但它仍然不能帮助我理解 CONFIG 生成器表达式的正确语法。

Answer 1

您不能在if 命令中使用生成器表达式，因为生成器表达式仅在配置过程结束时扩展，但需要立即评估if 条件。

表达式$<IN_LIST:<$CONFIG>,${CMAKE_CONFIGURATION_TYPES}> 有效 在其他生成器表达式的 BOOL 上下文中。但它只能用于产生另一个字符串，不能用于发出错误。

如果要检查用户指定的构建类型的正确性，应考虑以下事项：

1. 在 多配置 生成器（如 Visual Studio）上，构建类型由构建阶段的 --config 选项给出。 CMake 自动检查此类构建类型是否与CMAKE_CONFIGURATION_TYPES 匹配，因此无需手动检查。

2. 在 single-configiration 生成器（如 Makefile）上，构建类型是通过 CMAKE_BUILD_TYPE 变量指定的。所以生成器表达式中不需要引用构建类型。

3. 变量CMAKE_CONFIGURATION_TYPES 应该仅为多配置生成器指定。为单一配置生成器设置它可能会混淆一些脚本（例如FindXXX.cmake）。

因此，您可以通过以下方式检查构建类型（基于that answer 中的代码）

# Use custom variable for avoid setting CMAKE_CONFIGURATION_TYPES
# for single-configuration generators.
set(MY_CONFIGURATION_TYPES "Debug;Release")

# Check whether generator is single-configuration or multi-configuration
get_property(isMultiConfig GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
if(isMultiConfig)
    # Multi-configuration generator
    # Set possible values. CMake automatically checks correctness.
    set(CMAKE_CONFIGURATION_TYPES "${MY_CONFIGURATION_TYPES}" CACHE STRING "" FORCE) 
else()
    # Single-configuration generator
    if(NOT CMAKE_BUILD_TYPE)
        # If not set, set the build type to default.
        message("Defaulting to release build.")
        set(CMAKE_BUILD_TYPE Release CACHE STRING "" FORCE)
    else()
        # Check correctness of the build type entered by user
        # Note that the right operand for IN_LIST should be **variable**,
        # not just a list of values
        if (NOT (CMAKE_BUILD_TYPE IN_LIST MY_CONFIGURATION_TYPES))
            message(FATAL_ERROR "Incorrect build type")
        endif()
    endif()
    set_property(CACHE CMAKE_BUILD_TYPE PROPERTY HELPSTRING "Choose the type of build")
    # set the suggested values for cmake-gui drop-down list
    # Note, that CMake allows a user to input other values.
    set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "${MY_CONFIGURATION_TYPES}")
endif()

Answer 2

使用 CMake 包括两个阶段：

• 配置阶段cmake -S . -B _build或cd _build && cmake ..等
• 构建阶段cmake --build _build 或cd _build && make 等

生成器表达式$<suff> 在构建项目时扩展。它们在 CMake 脚本中不扩展。对于 CMake 脚本，在配置项目时，它只是文本。

要在 CMake 中进行比较，请在 CMake 中进行比较。我猜：

if (CMAKE_BUILD_TYPE IN_LIST CMAKE_CONFIGURATION_TYPES)