使用 Aeson 解析嵌入的 JSON

Question

我正在尝试解析表单的嵌入 JSON

{
  "foo":"bar",
  "baz":"\{\"somekey\":\"someval\"\}"
}

与 Aeson 在 Haskell 中。这是我的类型：

data BaseType = BaseType { foo :: String, baz :: EmbeddedType } deriving(Show)

instance FromJSON BaseType where
  parseJSON = withObject "BaseType" $ \o -> do
    foo <- o .: "foo"
    baz <- o .: "baz"
    return $ BaseType { foo=foo, baz=baz }

data EmbeddedType = EmbeddedType { somekey :: String }

instance FromJSON EmbeddedType where
  parseJSON = withObject "EmbeddedType" $ \o -> do
    somekey <- o .: "somekey"
    return $ EmbeddedType {somekey=somekey}

显然，BaseType 的 FromJSON 实例不起作用，因为它将其视为 Value String 而不是更多的 JSON 以供解析。我试图找到一种在我的FromJSON BaseType 实例中使用decodeEither 的方法，但这需要我做一些黑魔法才能从String 转换为ByteString，我觉得必须有一个更整洁的方法，可能与withEmbeddedJSON相关。

我怎样才能使它正常工作？

Answer 1

我猜应该是这样的（未经测试）：

instance FromJSON BaseType where
  parseJSON = withObject "BaseType" $ \o -> do
    foo <- o .: "foo"
    bazText <- o .: "baz"
    baz <- withEmbeddedJSON "EmbeddedType" parseJSON (String bazText)
    return $ BaseType { foo=foo, baz=baz }

或者您可以考虑将对withEmbeddedJSON 的调用转移到EmbeddedType 实例中；那么o .: "baz" 应该在BaseType 实例中工作，代价是不再拥有一个解析器的句柄，该解析器只执行EmbeddedType 解析而不去字符串化：

instance FromJSON BaseType where
  parseJSON = withObject "BaseType" $ \o -> do
    foo <- o .: "foo"
    baz <- o .: "baz"
    return $ BaseType { foo=foo, baz=baz }

instance FromJSON EmbeddedType where
  parseJSON = withEmbeddedJSON "EmbeddedType" . withObject "EmbeddedType" $ \o -> do
    somekey <- o .: "somekey"
    return $ EmbeddedType {somekey=somekey}