延续单子中的 StackOverflow

Question

使用以下延续单子：

type ContinuationMonad() =
    member this.Bind (m, f) = fun c -> m (fun a -> f a c)
    member this.Return x = fun k -> k x

let cont = ContinuationMonad()

我不明白为什么下面会出现堆栈溢出：

let map f xs =
    let rec map xs =
        cont {
            match xs with
            | [] -> return []
            | x :: xs ->
                let! xs = map xs
                return f x :: xs
        }
    map xs id;;

let q = [1..100000] |> map ((+) 1)

虽然以下没有：

let map f xs =
    let rec map xs =
        cont {
            match xs with
            | [] -> return []
            | x :: xs ->
                let! v = fun g -> g(f x)
                let! xs = map xs
                return v :: xs
        }
    map xs id;;

let q = [1..100000] |> map ((+) 1)

Answer 1

要修复您的示例，请将此方法添加到您的 monad 定义中：

member this.Delay(mk) = fun c -> mk () c

显然溢出的部分是map的递归调用中大输入列表的破坏。延迟它可以解决问题。

请注意，您的第二个版本将对 map 的递归调用置于另一个 let! 之后，后者对 Bind 和一个额外的 lambda 进行脱糖，实际上延迟了对 map 的递归调用。

在得出这个结论之前，我不得不寻找一些错误的线索。有帮助的是观察到StackOverflow 也被OCaml 抛出（尽管N 更高），除非递归调用被延迟。虽然F# TCO 有一些怪癖，但OCaml 更加成熟，所以这让我确信问题确实出在代码而不是编译器上：

let cReturn x = fun k -> k x
let cBind m f = fun c -> m (fun a -> f a c)

let map f xs =
  (* inner map loop overflows trying to pattern-match long lists *)
  let rec map xs =
    match xs with
      | [] -> cReturn []
      | x :: xs ->
        cBind (map xs) (fun xs -> cReturn (f x :: xs)) in
  map xs (fun x -> x)

let map_fixed f xs =
  (* works without overflowing by delaying the recursive call *)
  let rec map xs =
    match xs with
      | [] -> cReturn []
      | x :: xs ->
        cBind (fun c -> map xs c) (fun xs -> cReturn (f x :: xs)) in
  map xs (fun x -> x)

let map_fused f xs =
  (* manually fused version avoids the problem by tail-calling `map` *)
  let rec map xs k =
    match xs with
      | [] -> k []
      | x :: xs ->
        map xs (fun xs -> k (f x :: xs)) in
  map xs (fun x -> x)

Answer 2

F# 编译器有时不是很聪明 - 在第一种情况下，它计算 map xs 然后 f x 然后加入它们，所以 map xs 不在尾部位置。在第二种情况下，它可以轻松地将map xs 重新排序到尾部位置。