如何“要求”没有#lang 标题行的 Racket 模块？

Question

作为许多可能的示例之一，break-example.rkt 将是一个完全有效的 Java 程序，但 Racket 需要的 #lang mini-java 标头除外。

例如如果我在 Racket 中编写了 Java 解释器/编译器作为 Racket 模块语言，我怎么能说，“require 这个文件 Main.java 是用模块语言 mini-java 编写的，但没有任何特定于 Racket标题”？

（请注意，我对 Racket 的实践经验几乎为零。我正在针对 Racket + DrRacket 的特定用例对此进行评估，顺便说一下，这与 Java 无关。我搜索了文档，但是找不到任何方法来实现这一点。）

Answer 1

我现在无法运行或测试它，但也许您可以从这里开始并进行试验。它使用的主要是include/reader：

#lang racket
(require racket/include
         syntax/parse/define
         (for-syntax racket/syntax
                     racket/port
                     syntax/modread))

(define-simple-macro (require/mini-java path)
  #:with modname (generate-temporary #'path)
  (begin
    (include/reader path (mini-java-reader 'modname))
    (require 'modname)))

(begin-for-syntax
  ;; Symbol -> [Any InputPort -> Syntax]
  (define ((mini-java-reader modname) src input)
    (cond
      [(port-closed? input) eof]
      [else
       (define stx
         (with-module-reading-parameterization
           (lambda ()
             (read-syntax src
               (input-port-append #t
                 (open-input-string "#lang mini-java\n")
                 input)))))
       (close-input-port input)
       (syntax-parse stx
         [(module _ l . b)
          #`(module #,modname l . b)])])))