Haskell函数生成随机数，使得每次数字都与前一个不同答案

【问题标题】：Haskell function to generate random number such that each time the number is different from previous oneHaskell函数生成随机数，使得每次数字都与前一个不同
【发布时间】：2013-06-30 11:52:08
【问题描述】：

我想要一个随机生成的 6 位数字。保证我调用这个函数的次数不会超过 1000 次。该函数应该能够在我每次调用它时返回不同的数字。

我想像nextRandom 这样不带任何参数地调用这个函数。 Haskell 中是否有适合我的图书馆？我无法维持一颗种子。 Haskell 可以使用当前时间为seed。

更新：问题的背景。

我正在生成一个图形（点格式），我想确保所有顶点都有不同的标签。我可以通过将生成时间附加为标签来做到这一点，但我被这个想法所困扰，因为这样做是通过生成随机数来实现的。

【问题讨论】：

“因此，我可以期望该函数每次都返回不同的数字” - 疯狂的假设。如果您只是生成随机数，则有可能重复。事实上，概率比你的直觉说的更糟。检查生日悖论。
@KarolyHorvath 谢谢。修正了语言。
卡罗莉，虽然你说的是真的，但我不喜欢使用“悖论”这个词，因为它不是不合逻辑或类似的：P 就像说“蒙蒂霍尔悖论”一样，我更喜欢“蒙蒂霍尔问题”。
[1..1000] 给你 1000 个随机数。 :)
如果@augustss 随机列表可能缺少某种令人惊讶的元素:-)，您可以随时在其上调用“shuffle”。

标签： haskell random

【解决方案1】：

纯函数（如nextRandom，没有参数）就像数学函数。在每次调用时，它们都会使用相同的参数产生相同的结果。

所以你的要求是不可能的，因为

您期望随机数。
您希望该函数有某种内存来知道哪些数字已经生成。

只需采用 Haskell 方式，将种子或随机生成器传递给函数，或使用 monad。如果有帮助，您可以提前创建 1000 个数字，然后从列表中检索它们。

【讨论】：

【解决方案2】：

你不能有一个每次都返回一个不同数字的纯函数。它的输出取决于它之前的调用，而不仅仅是它的参数。但是您可以创建一个包含到目前为止生成的数字集的 monad，然后重试生成一个随机数，直到找到一个迄今为止尚未生成的数字。对于以下示例，我使用了 MonadRandom 包。

import Control.Monad
import Control.Monad.Random
import Control.Monad.State
import Data.IntSet (IntSet)
import qualified Data.IntSet as IS
import System.Random (getStdGen)

type RandDistinct g a = StateT IntSet (Rand g) a

evalDistinct :: RandomGen g => RandDistinct g a -> g -> a
evalDistinct k = evalRand (evalStateT k IS.empty)

上述类型使用StateT 来增强随机数生成器，以记住迄今为止生成的数字集。当我们想要评估这个 monad 中的计算时，我们从一个空集开始，然后使用 evalRand 评估内部计算。

现在我们可以编写一个每次返回一个不同数字的函数：

nextDistinct :: RandomGen g => (Int,Int) -> RandDistinct g Int
nextDistinct range = loop
  where
    -- Loop until we find a number not in the set
    loop = do
        set <- get
        r <- getRandomR range
        if IS.member r set
          then loop -- repeat
          else put (IS.insert r set) >> return r

并测试它是如何工作的：

main = getStdGen >>= print . evalDistinct (replicateM 50 $ nextDistinct (10, 99))

请注意，nextDistinct 使用了一个简单的策略 - 如果集合中已经存在一个新数字，则重试生成它。只要碰撞次数少，这种方法就可以正常工作。

【讨论】：

【解决方案3】：

不完全是您正在寻找的，但如果您只需要一个通用的无替换采样例程，您可以使用类似 this example module 我在 SO 上提出的另一个问题。

只需提前生成您需要的许多不同的六位数字，然后在任何您想要的地方使用它们。例如：

import System.Random.MWC
import Sample

main :: IO ()
main = do
  ns <- withSystemRandom . asGenIO $ \gen -> sample [100000..999999] 10 gen
  print ns

-- [754056,765889,795475,389702,120426,740641,556446,490338,534738,213852]

【讨论】：

【解决方案4】：

这里可能有助于更多地了解您所询问的函数将被使用的上下文。我远非专家，但这样的事情能帮到你吗？

import Control.Monad.Random

rnd :: (RandomGen g) => Rand g Int
rnd = getRandomR (100000,999999)

main = do
  putStr "\nPlease type 'nextRandom' or 'quit':\n> "
  mainLoop [] where
    mainLoop memory = do
      command <- getLine
      case command of
        "nextRandom" -> do next <- randomLoop memory
                           putStr (show next ++ "\n> ")
                           mainLoop (next:memory)
        "quit"       -> return ()
        otherwise    -> putStr "\n> "
    randomLoop memory = do  
      value <- evalRandIO rnd
      if elem value memory 
         then randomLoop memory
         else return value

【讨论】：