Lisp - 替换列表中元素的所有外观[重复]

Question

我尝试在所有主列表级别将列表中的某个元素 E 替换为另一个列表 K。

(defun replaceList(l e k)
  (cond
    ((null l) nil)
    ((equal e (car l)) (cons k (replaceList (cdr l) e k)))
    ((listp (car l))
     ((equal e (car (car l))) (cons k (replaceList (cdr (car l)) e k))))
    (t (cons (car l) (replaceList (cdr l) e k)))))

例子：

(replaceList '(3 1 2 (6 1) 7 (5 (5 (3 1))) 9) '1 '(99 99))
--> (3 (99 99) 2 (6 (99 99)) 7 (5 (5 (3 (99 99) ) ) ) 9)

我得到一些带有 lambda 表达式的错误信息。

另外，我尝试了而不是 listp(car l) "block" ： ((listp (car l)) (cons k (replaceList (cdr (car l)) e k)))。 我得到一些奇怪的东西： (2 1 3 ( 6 1 7) 7 1 2 ) -> (2 (99 99) 3 (99 99) (99 99) 7)

Answer 1

错误

您的“lambda 表达式消息”是由于 listp 子句中 equal 周围的一组额外括号。记住，Lisp parentheses are meaningful。

使用标准库！

ANSI Common Lisp 有 subst 可以满足您的需求：

(subst '(99 99) 1 '(3 1 2 (6 1) 7 (5 (5 (3 1))) 9) :test #'equal)
==> (3 (99 99) 2 (6 (99 99)) 7 (5 (5 (3 (99 99)))) 9)

你的算法

由于您是在 tree 上操作，而不是 list（您说“所有 主列表级别"），您应该同等对待car 和cdr：

(defun my-subst (new old tree &key (test #'eql))
  (cond ((funcall test old tree)
         new)
        ((atom tree)
         tree)
        (t
         (cons (my-subst new old (car tree) :test test)
               (my-subst new old (cdr tree) :test test)))))
(my-subst '(99 99) 1 '(3 1 2 (6 1) 7 (5 (5 (3 1))) 9) :test #'equal)
==> (3 (99 99) 2 (6 (99 99)) 7 (5 (5 (3 (99 99)))) 9)

或者，简化（没有&key 和 funcall):

(defun my-subst (new old tree)
  (cond ((equal old tree)
         new)
        ((atom tree)
         tree)
        (t
         (cons (my-subst new old (car tree))
               (my-subst new old (cdr tree))))))