【问题标题】:Common Lisp: non-nil arguments and their names to alist, how?Common Lisp:非零参数及其名称到 alist,如何?
【发布时间】:2011-04-12 06:51:23
【问题描述】:

我对 Common Lisp 和编程很陌生,我正在尝试编写一个将所有非零参数转换为 alist 的函数。到目前为止我能想到的唯一方法是:

(let ((temp nil))
    (if arg1
        (setf temp (acons 'arg1 arg1 nil)))
    (if arg2
        (setf temp (acons 'arg2 arg2 temp)))
    ...
    (if arg20-ish
        (setf temp (acons 'arg20-ish arg20-ish temp)))

    (do-something-with temp))

这似乎不是很优雅,它会因为很多参数而变得混乱,并且需要更改这些参数。 我正在寻找一种更聪明的方法来做这件事,既是为了编写这个特定的函数,也是为了学习如何在 Lisp 和/或函数式编程中思考。

对我来说,棘手的部分是弄清楚如何获取参数的名称或使用什么符号,而无需对每个案例进行手动编码。如果 &rest 提供了 arg 名称,那么使用循环或 mapcar 过滤掉 NIL 会很容易,但由于它没有,我看不出如何“自动化”这个。
如果人们认为这种方式不自然,我对所描述的解决方案以外的其他解决方案完全感兴趣。

编辑:下面是我正在尝试做的一个示例:

创建了一个对象,具有不固定数量的数据对和一些标签,例如:

user = "someone"  
creation-time = (get-universal-time)  
color-of-sky = "blue"  
temperature-in-celsius = 32  
language = "Common Lisp"
...  
tags = '("one" "two" "three")

这些属性(即键/参数名称)每次都可能不同。然后将新对象添加到集合中;我认为该数组可能运行良好,因为我想要恒定的访问时间并且只需要一个数字 ID。
该集合将无限期地保存越来越多的此类自定义对象。
我希望能够快速访问与这些对象中使​​用的任何标签的任意组合匹配的所有对象。
由于该数组应该在很长一段时间内存储越来越多的数据,因此我不想在每次需要搜索标签时解析其中的每个项目。因此,我还将带有给定标签的每个对象的索引存储在标签名称下的哈希表中。我已经编写了这个函数,我觉得困难的是弄清楚如何收集数据并将其转换为 alist 或任何我可以轻松解析、索引和存储的东西。

【问题讨论】:

  • 我认为你在做一些概念上的错误。您能否提供一些示例数据以及它们应该如何处理?

标签: lisp arguments common-lisp


【解决方案1】:

此宏将定义一个函数,该函数在主体执行期间将其非零参数转换为 alist:

(defmacro defnamed (fun-name alist-sym (&rest args) &body body)
  `(defun ,fun-name (,@args)
     (let ((,alist-sym))
      ,@(mapcar
         (lambda (s)
          `(when ,s
            (push (cons ',s ,s) ,alist-sym)))
         (reverse args))
      ,@body)))

演示:

(defnamed make-my alist (a b c) 
  alist)

(make-my 1 NIL 3)

=> ((A . 1) (C . 3))

【讨论】:

  • 谢谢,我想这是我现在要用的,因为它稍微短一些。如果我必须提前定义 alist 属性名称,我想不出为什么我需要其他答案中的关键字。是否可以在编译时不知道这些的情况下创建 alist?
【解决方案2】:

这是一种使用宏的解决方案:

(defmacro named-args (fun-name alist-sym (&rest syms) &body body)
  `(defun ,fun-name (&key ,@syms)
     (declare (special ,@syms))
     (let ((,alist-sym
            (loop
               for s in ',syms
               collecting (cons s (symbol-value s)))))
       ,@body)))

然后您可以将它与类似的东西一起使用

(named-args f u (a b c)
  (format t "~A~%" u))

扩展为

(DEFUN F (&KEY A B C)
  (DECLARE (SPECIAL A B C))
  (LET ((U
         (LOOP FOR S IN '(A B C)
            COLLECTING (CONS S (SYMBOL-VALUE S)))))
    (FORMAT T "~A~%" U)))

最后,打电话会给

(f :a 3) => ((A . 3) (B) (C))

请注意,我们需要特殊声明,否则符号值不起作用(您需要符号值的全局绑定)。我找不到摆脱它的方法。

再次查看您的问题,您似乎实际上不希望未通过的关键字参数。在这种情况下,您可以解析 &rest 参数(尽管这是一个平面列表,因此您需要将其分成两部分进行映射),或者您可以按如下方式修改宏:

(defmacro named-args (fun-name alist-sym (&rest syms) &body body)
  `(defun ,fun-name (&key ,@syms)
     (declare (special ,@syms))
     (let ((,alist-sym
            (loop
               for s in ',syms
               when (symbol-value s)
               collecting (cons s (symbol-value s)))))
       ,@body)))

然后你得到

(f :a 3) => ((A . 3))

【讨论】:

  • 或者他可以用 &REST 参数定义 F 并且宏会自己解析关键字列表。
  • 这不起作用,因为 &rest 只包含实际指定的参数。所以 (defun f (&rest r &key a b c) ...) 调用 (f :a 1) 将 r 绑定到 '(a 1)。
  • 嗯,重新阅读这个问题,看起来这可能是他想要的。我已经对我的回答进行了编辑:希望这会更有帮助。
  • 谢谢,这很有帮助。我已经盯着它看了一段时间并尝试了它,它似乎是我正在寻找的东西 - 坦率地说我还不能确定,因为我的大脑在试图将自己包裹在周围之后停止工作使用宏的想法。 :P 我认为这对我看这个阶段非常有用,但是我仍然必须提前知道 alist-keys,不是吗?另外,能否请您展示如何沿着 &rest 列表进行映射?
猜你喜欢
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 2021-11-15
  • 1970-01-01
  • 1970-01-01
相关资源
最近更新 更多