如何在递归中使用差异列表？答案

【问题标题】：How to use difference lists in recursion?如何在递归中使用差异列表？
【发布时间】：2018-01-29 09:59:57
【问题描述】：

下面程序的意图如下 clist_d(f(a,f(a,a)),R) 结果是所有基本参数的列表，例如 R = [a,a,a]

%Difference list append.
diffapp(X-Y,Y-Z,X-Z). 

%2 base case
clist_d(a,[a]).
clist_d(b,[b]).
clist_d(c,[c]).

%If we get a term f(X,Y) the first term of such list is the element in X,followed by the elements in Y
clist_d(f(X,Y),R) :-
    clist_d(X,R1),
    clist_d(Y,R2),
    diffapp([R1|H]-H,R2-[],R-[]).

%We can also get a g
clist_d(g(X,Y),R) :-
    clist_d(X,R1),
    clist_d(Y,R2),
    diffapp([R1|H]-H,R2-[],R-[]).

但是，该程序包含一个错误。使用以下查询运行程序：

?- clist_d(f(a,a),R).
R = [[a],a] ?

产生如上所示的错误，单独测试差异列表我得到以下结果

?- X = [a,b,c|T], Y = [1,2,3],diffapp(X-T,Y-[],R-[]).
X = [a,b,c,1,2,3],
T = [1,2,3],
Y = [1,2,3],
R = [a,b,c,1,2,3] ? 
yes

我在我的主程序中犯了一个错误，但我不知道要添加什么来使我的 diffapp 在那里工作。

【问题讨论】：

为什么？你想达到什么目标？您想在使用 clist_d(X,Y) 时找到一个包含单个原子的列表吗？为什么你的尾巴叫H？为什么将输出列表用作列表的头部而不是列表的尾部？您使用了哪些查询来获得底部输出？
了解差异列表的有用资源：Understanding difference lists
所有基本术语的列表，例如R = [a,a,a]。您实际上是指基本参数的列表。 f(a,a) 是一个基本术语，f(a,f(a,a)) 是一个基本术语，等等。a 在这些情况下是一个参数。另外，您的问题真的仅限于原子a、b 和c，还是您需要能够处理，例如e？如果是这种情况，您可以概括 Tomas 给出的解决方案：clist_d(X,[X|R],R) := atom(X).
@lurker 你说的完全正确，我的意思是地面物品清单。是的，这是正确的，我的程序仅限于原子 a、b、c。我将编辑我的帖子，让未来的读者更清楚。
@G_V H 是在这种情况下的孔的助记符，我将编辑我的第二个查询，以便将来的读者更清楚。

标签： prolog difference-lists

【解决方案1】：

对于差异列表，您希望在任何地方传递一对参数，并且确实需要任何附加，因此顶级调用应该是：

clist_d(f(a,f(a,a)),R,[])

输出中嵌套的问题是因为您的基本案例返回一个列表 (R1)，然后在调用中追加您的 cons ([R1|H])。没有附加，这不会发生。

clist_d(f(X,Y),R0,R) :-
  clist_d(X,R0,R1),
  clist_d(Y,R1,R).

clist_d(g(X,Y),R0,R) :-
  clist_d(X,R0,R1),
  clist_d(Y,R1,R).

clist_d(a,[a|R],R).
clist_d(b,[b|R],R).
clist_d(c,[c|R],R).

生产：

| ?- clist_d(f(a,f(a,a)),R,[]).
R = [a,a,a] ? ;
no

【讨论】：