【问题标题】:How to define a function in LISP which passes two Forms and then executes them randomly如何在 LISP 中定义一个传递两个表单然后随机执行它们的函数
【发布时间】:2014-03-09 23:03:41
【问题描述】:

我是 LISP 的新手,我目前正在尝试定义一个函数,该函数将传递另外两种随机执行的形式。因此,例如,如果我要执行任何表单,它会从返回结果的选择中随机执行其中一个表单。

有人知道这方面的任何例子吗?我似乎对 LISP 了解得不够多,无法形成一个网络搜索来返回我正在寻找的结果。

【问题讨论】:

    标签: lisp common-lisp


    【解决方案1】:

    用宏包装函数式实现……

    Barmar's answer 展示了如何使用函数来做到这一点。我认为这是解决这个问题的最明智的实施技术。 Wojciech Gac's answer 建议使用宏来执行此操作。我认为这是解决此问题的最自然的编程接口(尽管如 cmets 中所述,该答案中的宏存在一些问题)。最后,我认为将这两种技术结合起来是值得的,这样您就可以从实现中受益(如果需要,您可以稍后使用函数对象),以及在其余时间使用方便的接口。

    (defun call-one (functions)
      (funcall (nth (random (length functions)) functions)))
    
    (defmacro one-of (&body forms)
      `(call-one (list ,@(mapcar (lambda (form)
                                   `(lambda ()
                                      ,form))
                                 forms))))
    
    (call-one (list (constantly 3) (constantly 4)))
    ;=> 4 ; or 3
    
    (one-of 3 4)
    ;=> 3 ; or 4
    

    在我看来,这种类型的宏实现技术,其中主要功能被实现为一个函数,而宏是根据函数实现的,在适用时是一种很好的做法。将功能实现为函数通常更容易,因为您对名称捕获、构造表单等的担忧更少。有时,您可以使用功能实现,因此您可以增加一点灵活性。根据函数实现宏意味着宏实际上是你的语法糖;从概念上讲,您需要做的就是将一些单独的表单包装在匿名函数中,而宏的任务并不太复杂。当然,这并不适用于每个宏,但在我看来,当它适用时,它会导致代码更易于维护,并且从一开始就更少错误。

    但要避免多余的工作……

    不过,这里有一个值得注意的问题。 one-of 的扩展创建一个列表并将其传递给call-one:

    (macroexpand-1 '(one-of 3 4))
    ;=> (CALL-ONE (LIST (LAMBDA () 3) (LAMBDA () 4)))
    

    call-one 计算函数列表的长度并生成一个随机数。对于大多数调用来说,这很好,但对于 one-of 的扩展来说并不是很好,因为这意味着我们要重新计算一个永远不会一次又一次改变的列表的长度。当我们使用one-of 时,我们可以在宏扩展时计算(length functions),但我们仍然需要一种方法将其提供给call-one。因此,我们可以通过向call-one 添加一个默认为(length functions) 的可选参数来稍微改变功能接口。在one-of的扩展中,我们只是提供了一个常量值。

    (defun call-one (functions &optional (len (length functions)))
      (funcall (nth (random len) functions)))
    
    (defmacro one-of (&body forms)
      `(call-one (list ,@(mapcar (lambda (form)
                                   `(lambda ()
                                      ,form))
                                 forms))
                 ,(length forms)))
    

    因此我们得到了这个扩展:

    (macroexpand-1 '(one-of 3 4))
    ;=> (CALL-ONE (LIST (LAMBDA () 3) (LAMBDA () 4)) 2)
    

    【讨论】:

      【解决方案2】:

      这需要任意数量的函数,并随机调用其中一个:

      (defun execute-one (&rest funcs)
        (let* ((random-pos (random (length funcs)))
               (func (nth random-pos funcs)))
          (funcall func)))
      
      (execute-one
        (lambda () (print 3))
        (lambda () (print 5))
        (lambda () (print 10)))
      

      【讨论】:

        【解决方案3】:

        嗯,在 Barmar 的回答中,提供给 execute-one 的表单必须是 lambda 类型并且是零参数。我建议将其实现为宏:

        (defmacro execute-one (&body funcs)
          `(let* ((random-pos (random (length ',funcs)))
              (func (nth random-pos ',funcs)))
             (eval func)))
        

        现在您可以提供任意表单,​​execute-one 将随机评估其中一个。

        例子:

        (execute-one
          (+ 10 100)
          (* 234 934)
          (expt 2 100))
        
        => 110
        

        编辑: 我已经能够从中驱除eval:

        (defmacro execute-one (&body funcs)
          `(let* ((random-pos (random (length ',funcs)))
              (func (nth random-pos ',funcs)))
             (apply #'funcall func)))
        

        @Rainer,除了eval,你能详细说明为什么它的风格不好吗?

        【讨论】:

        • 大家好,感谢您的回复。他们正在帮助我更好地理解这一点。一旦我创建了一些东西,我就会发布和展示。但只是想说感谢您的快速回复。 :)
        • 这个宏风格不好。特别是因为它使用 EVAL。
        • @Wojciech 格式化(缩进)也可能需要一些工作,但这不是一个严重的技术问题。更重要的是,这不起作用。 (i) 最终的宏版本不能作为您给出的第一个示例。你可以(eval '(+ 10 100)),但你不能(apply #'funcall '(+ 10 100))。 (ii) 如果其中一个代码块碰巧使用了名为random-pos 的变量,会发生什么? (iii) 虽然您每次都需要生成一个随机数,但没有理由每次都调用length。由于提供的表单数量是固定的,您可以在编译时计算(length funcs)。
        • @JoshuaTaylor,至于 (i),我实际上可以在 SBCL 中运行 (apply #'funcall '(+ 10 100)) 并得到 110 作为响应。 “不能”到底是什么意思? :)
        • @WojciechGac 对不起,那个特定的例子确实有效,因为你可以做到(funcall '+ '10 '100)。但是,您不能将funcall 应用于任意表单并使其正常工作。例如,你不能做(apply #'funcall '(let ((x 10)) (+ x 100))),因为你不能做(funcall 'let '((x 10)) '(+ x 100))。另外,你真的应该删除eval 版本;它在很多情况下根本行不通。例如,(let ((x 10)) (execute-one x)) 将失败。
        猜你喜欢
        • 1970-01-01
        • 1970-01-01
        • 1970-01-01
        • 2014-12-25
        • 2021-09-01
        • 1970-01-01
        • 1970-01-01
        • 2015-02-11
        • 1970-01-01
        相关资源
        最近更新 更多