delphi 7函数结果可以是未定义的

Question

我写了这个函数，它比较字符串，如果匹配则返回 TRUE，如果不匹配则返回 FALSE。

唯一的问题是，当我编译时，我得到一个错误，说结果可能是未定义的。我知道这不是问题，因为在这种特殊情况下只有两种可能的结果，但我是一个完美主义者，我想变得更好。 你们中的任何人都可以启发我吗？

function filterUPC(upc: String): Boolean; 
var
  i, pos1: integer;
  Plano: TStringList;
  upcPlano: String;
begin
  Plano := TStringList.Create;
  if (fmMain.lblPlanook.Visible) and 
     not (fmMain.lblPlanook.Caption = 'INCOMPATIBLE') then
  begin
    Plano.LoadFromFile(fmMain.ebPlano.Text);
    for i := 0 to Plano.Count - 1 do
    begin
      pos1:=AnsiPos(';', Plano[i]);
      upcPlano := AnsiMidStr(Plano[i], pos1 + 1, 12);
      if (upc = upcPlano) then
      begin
        Result := TRUE;
        Break;
      end
      else if (i = Plano.Count - 1) then
      begin
        Result := FALSE;
      end;
    end;
  end
  else
  begin
    Result := FALSE;
  end;
  Plano.Free;
end;

Answer 1

如果Plano 为空，则您的结果未定义。在这种情况下，for 循环永远不会执行，Result 永远不会被设置。

另外，您真的应该将 TStringList create/free 包装在 try/finally 中（因为您是完美主义者；）

我会这样做：

function filterUPC(upc: String): Boolean;
var
  i, pos1: integer;
  Plano: TStringList;
  upcPlano: String;
begin
  Result := FALSE;
  Plano := TStringList.Create;
  try
    if (fmMain.lblPlanook.Visible) and (fmMain.lblPlanook.Caption <> 'INCOMPATIBLE') then
    begin
      Plano.LoadFromFile(fmMain.ebPlano.Text);
      for i := 0 to Plano.Count -1 do
      begin
        pos1 := AnsiPos(';', Plano[i]);
        upcPlano := AnsiMidStr(Plano[i], pos1 + 1, 12);
        if (upc = upcPlano) then
        begin
          Result := TRUE;
          Break;
        end;
      end;
    end
  finally
    Plano.Free;
  end;
end;

我已将Result:=FALSE; 添加到顶部，并删除了else 检查。 try/finally 保证 Plano 将被释放，即使引发异常。