如何使用 XML::LibXML 列出 XML 节点属性？

Question

给定以下 XML sn-p：

<outline>
  <node1 attribute1="value1" attribute2="value2">
    text1
  </node1>
</outline>

我如何得到这个输出？

outline
node1=text1
node1 attribute1=value1
node1 attribute2=value2

我查看了use XML::LibXML::Reader;，但该模块似乎只提供对其名称引用的属性values的访问。以及我首先如何获得属性名称列表？

Answer 1

这样的事情应该可以帮助你。

您的问题尚不清楚<outline> 是数据的根元素，还是隐藏在更大文档中的某个地方。还不清楚您希望解决方案有多通用-例如您想以这种方式转储整个文档吗？

无论如何，这个程序以相当简洁的方式从给定的 XML 输入中生成您请求的输出。

use strict;
use warnings;
use 5.014;     #' For /r non-destructive substitution mode

use XML::LibXML;

my $xml = XML::LibXML->load_xml(IO => \*DATA);

my ($node) = $xml->findnodes('//outline');

print $node->nodeName, "\n";

for my $child ($node->getChildrenByTagName('*')) {
  my $name = $child->nodeName;

  printf "%s=%s\n", $name, $child->textContent =~ s/\A\s+|\s+\z//gr;

  for my $attr ($child->attributes) {
    printf "%s %s=%s\n", $name, $attr->getName, $attr->getValue;
  }
}

__DATA__
<outline>
  <node1 attribute1="value1" attribute2="value2">
    text1
  </node1>
</outline>

输出

outline
node1=text1
node1 attribute1=value1
node1 attribute2=value2

Answer 2

你可以通过$e->findnodes( "./@*");找到属性列表

下面是一个解决方案，它使用纯 XML::LibXML，而不是 XML::LibXML::Reader，它适用于您的测试数据。不过，它可能对额外的空白和混合内容很敏感，因此在使用之前先在真实数据上进行测试。

#!/usr/bin/perl

use strict;
use warnings;

use XML::LibXML;

my $dom= XML::LibXML->load_xml( IO => \*DATA);
my $e= $dom->findnodes( "//*");

foreach my $e (@$e)
  { print $e->nodeName;

    # text needs to be trimmed or line returns show up in the output
    my $text= $e->textContent;
    $text=~s{^\s*}{};
    $text=~s{\s*$}{};

    if( ! $e->getChildrenByTagName( '*') && $text)
      { print "=$text"; }
    print "\n"; 

    my @attrs= $e->findnodes( "./@*");
    # or, as suggested by Borodin below, $e->attributes

    foreach my $attr (@attrs)
      { print $e->nodeName, " ", $attr->nodeName. "=", $attr->value, "\n"; }
  }
__END__
<outline>
  <node1 attribute1="value1" attribute2="value2">
    text1
  </node1>
</outline>