Spring4d：具有所有者的自动工厂：TComponent 参数？

Question

使用Spring4d，你可以像这样注册自定义工厂

aContainer.RegisterInstance<TFunc<string, TMyObject>>(function(aName : string):TMyObject
begin
    Result := TMyObject.Create(aName);
end);

以这种方式，我相信对于从 TComponent 继承的每个依赖项，想要传递所有者的人会这样做

// Registrations 

aContainer.RegisterInstance<TFunc<TComponent, TMyObject>>(function(Owner : TComponent):TMyObject
begin
    Result := TMyObject.Create(Owner);
end);

// Then in code

constructor TMyClass.Create(aFctry : TFunc<TComponent, TMyObject>);
begin
    fObj := aFctry(Self);
end;

或者也可以

aContainer.RegisterType<TMyObject, TMyObject>;

// In code

constructor TMyClass.Create(aObj : TMyObject);
begin
    fObj := aObj;
    InsertComponent(aObj);
end;

不过，这很容易出错/添加代码只是为了传递所有者。有没有一种内置的方法来获取一个将 TComponent 作为参数的工厂，而无需事先在容器中注册它？

因为我经常会使用

constructor MyObject.Create(aDep : TFunc<TMyDep>);

不注册TFunc<TMyDep>依赖，只注册TMyDep类型。

可以传递类似的东西

constructor MyObject.Create(aDep : TFunc<TComponent, TMyDep>);

无需在容器中注册？

Answer 1

据我所知，没有注册是不可能的。

但是，有一种方法可以摆脱使用 Spring.Container.Common 中不同的IFactory<T,TResult> 接口对 1-4 个参数进行手动工厂实现，这将在注册时由 DI 容器自动实现。

所以你可以这样注册：

aContainer.RegisterType<TMyObject>;
aContainer.RegisterType<IFactory<TComponent, TMyObject>>.AsFactory;

像这样注册工厂，不需要你自己实现——容器会为你解决。

这意味着，当您需要TMyObject 的实例时，您不再直接（从容器）请求它。相反，您确实请求IFactory<TComponent, TMyObject> 的实例，其中TComponent 是TMyObject 构造函数接受的唯一参数。

作为使用来自另一个类TSomeClass 的构造函数注入的示例（其中TSomeClass 也是TComponent 的后代），它如下所示：

constructor TSomeClass.Create(const AMyObjectFactory: IFactory<TComponent, TMyObject>);
begin
  fMyObjectInstance := AMyObjectFactory(Self);
end;

至少对我来说，这让事情变得容易多了。

Answer 2

如果我理解正确，你尽量避免这样的例行代码：

aContainer.RegisterInstance<TFunc<TComponent, TMyFirstObject>>(function(Owner : TComponent):TMyFirstObject
begin
    Result := TMyFirstObject.Create(Owner);
end);

aContainer.RegisterInstance<TFunc<TComponent, TMySecondObject>>(function(Owner : TComponent):TMySecondObject
begin
    Result := TMySecondObject.Create(Owner);
end);

aContainer.RegisterInstance<TFunc<TComponent, TMyThirdObject>>(function(Owner : TComponent):TMyThirdObject
begin
    Result := TMyThirdObject.Create(Owner);
end);

好吧，您可以使用过程 RegisterComponentDescendant 定义帮助类，它会为您创建结构，因此您编写的代码将是这样的：

aContainer.RegisterComponentDescendant<TMyFirstObject>;
aContainer.RegisterComponentDescendant<TMySecondObject>;
aContainer.RegisterComponentDescendant<TMyThirdObject>;

并像以前一样做。 Helper 类是这样定义的：

  TContainerHelper = class helper for TContainer
  public
    procedure RegisterComponentDescendant<TMyObject: TComponent>;
  end;

及其实现：

procedure TContainerHelper.RegisterComponentDescendant <TMyObject>;
begin
  self.RegisterInstance<TFunc<TComponent, TMyObject>>(
    function(Owner : TComponent):TMyObject
    begin
        Result := TMyObject.Create(Owner);
    end);
end;