通过单击 Excel VBA 中的上一个来创建一系列按钮

Question

我正在用 Excel VBA 练习一个类模块。

我手动插入了一个空白用户表单。从现在开始，将不再手动添加任何控件。

一旦你初始化了用户窗体，它就会在窗体的左上角出现一个命令按钮。

现在，单击该按钮，您将在第一个按钮的正下方看到另一个命令按钮。
单击新创建的按钮应在前一个按钮下方创建另一个按钮。只要您继续单击新创建的命令按钮，该过程就会继续进行。

问题
我在初始化用户窗体时创建了第一个按钮，并在下面创建了一个新按钮。
之后，单击第二个/新创建的按钮时没有任何反应。

用户表单代码

Dim A As New Class2       ' Create an object of the Class (where we declared the events).

Private Sub UserForm_Initialize()

    ' Create and add the button control.
    Dim btEx As MSForms.CommandButton
    Set btEx = UserForm1.Controls.Add("Forms.CommandButton.1")
    
    With btEx
        .Top = 12
        .Left = 12
        .Width = 72
        .Height = 36
        .Caption = "Click Me"
    End With
    
    Set A.btEvents = btEx
    
End Sub

类模块

Public WithEvents btEvents As MSForms.CommandButton

Private Sub btEvents_click()
        
    ' Create and add the button control.
    Dim btEx As MSForms.CommandButton
    Set btEx = UserForm1.Controls.Add("Forms.CommandButton.1")
    
    With btEx
        .Top = 30
        .Left = 30
        .Width = 72
        .Height = 36
        .Caption = "Click Me"
    End With
        
End Sub

我无法将事件分配给类模块中动态创建的命令按钮。

是我遗漏了什么还是在平台上不可能？

Answer 1

实现一个类的集合，其中每个类都包含一个按钮，是完成这项工作的关键。这种常用方法的缺点是类包含对 UserForm 的引用，并且事件在类本身中处理。理想情况下，我们希望将所有按钮代码返回到用户窗体中，包括事件处理。

由于不能将 Collections 声明为 WithEvents，如何做到这一点？这可以通过全局通知机制来完成：

用户表单

Option Explicit

Private WithEvents MyNotifier As Notifier
Private MyControls As Collection
    
Private Sub UserForm_Initialize()
   Set MyNotifier = GetNotifier()
   Set MyControls = New Collection
   AddButton
End Sub

Private Sub MyNotifier_Click()
   AddButton
End Sub

Private Sub AddButton()
   Dim c As MSForms.CommandButton
   Set c = UserForm1.Controls.Add("Forms.CommandButton.1")
   c.Width = 72
   c.Height = 36
   c.Top = UserForm1.Controls.Count * c.Height
   c.Left = 12
   c.Caption = "Click Me"

   Dim mc As MyControl
   Set mc = New MyControl
   mc.Add c
   MyControls.Add mc
End Sub

此架构有 3 个支持模块。第一个是一个包含全局通知器的模块。我们通过 GetNotifier 方法创建和访问这个通知程序。这种方法保证只有一个实例。

模块

Option Explicit

Private m_Notifier As Notifier

Public Function GetNotifier() As Notifier
   If m_Notifier Is Nothing Then Set m_Notifier = New Notifier
   
   Set GetNotifier = m_Notifier
End Function

第二个是定义通知器的类。这个单例类是一个事件协调器。它允许重定向事件，在本例中是从 MyControl 类返回到 UserControl。

通知程序类

Option Explicit

Public Event Click()

Public Function Click()
   RaiseEvent Click
End Function

第三个是持有按钮的类。对按钮单击事件的响应是调用我们的通知程序的方法，该方法反过来将事件返回给 UserControl：

MyControl 类

Option Explicit

Private MyNotifier As Notifier
Private WithEvents btEx As MSForms.CommandButton

Public Sub Add(ByVal c As MSForms.CommandButton)
   Set MyNotifier = GetNotifier()
   Set btEx = c
End Sub

Private Sub btEx_Click()
   MyNotifier.Click
End Sub

Answer 2

你可以试试这个。有点匆忙，所以如果出现问题也不会感到惊讶，但如果出现问题，明天会回来。

表格后面

Private col As Collection

Private Sub UserForm_AddControl(ByVal Control As MSForms.Control)

Dim cl As Class2
Dim ctl As MSForms.CommandButton

Set col = New Collection

For Each ctl In Me.Controls
    Set cl = New Class2
    Set cl.btEvents = ctl
    col.Add cl
Next ctl

End Sub

Private Sub UserForm_Initialize()

Dim btEx As MSForms.CommandButton
Set btEx = UserForm1.Controls.Add("Forms.CommandButton.1")

With btEx
    .Top = 12
    .Left = 12
    .Width = 72
    .Height = 36
    .Caption = "Click Me"
End With

End Sub

类模块 这里唯一的改变是添加一些间距，这样按钮就不会出现在彼此的顶部。

Public WithEvents btEvents As MSForms.CommandButton

Private Sub btEvents_click()

Dim btEx As MSForms.CommandButton
Set btEx = UserForm1.Controls.Add("Forms.CommandButton.1")

With btEx
    .Top = 30 * UserForm1.Controls.Count
    .Left = 30
    .Width = 72
    .Height = 36
    .Caption = "Click Me"
End With

End Sub