ParserRule 匹配错误的标记

Question

我正在尝试学习一点 ANTLR4 并为某些 4GL 语言定义语法。

这就是我所拥有的：

compileUnit
:
    typedeclaration EOF
;

typedeclaration
:
    ID LPAREN DATATYPE INT RPAREN
;

DATATYPE
:
    DATATYPE_ALPHANUMERIC
    | DATATYPE_NUMERIC
;

DATATYPE_ALPHANUMERIC
:
    'A'
;

DATATYPE_NUMERIC
:
    'N'
;

fragment
DIGIT
:
    [0-9]
;

fragment
LETTER
:
    [a-zA-Z]
;

INT
:
    DIGIT+
;

ID
:
    LETTER
    (
        LETTER
        | DIGIT
    )*
;

LPAREN
:
    '('
;

RPAREN
:
    ')'
;

WS
:
    [ \t\f]+ -> skip
;

我希望能够解析的内容：

测试（A10）

我得到了什么：

typedeclaration:1:6: 不匹配的输入 'A10' 需要 DATATYPE

但是我可以写：

测试（A 10）

为什么我需要在这里放一个空格？ LPAREN DATATYPE 本身是有效的，所以中间不需要空格。 INT RPAREN 也在工作。 为什么 DATATYPE 和 INT 之间需要一个空格？我对此有点困惑。 我猜它是匹配 ID，因为它是“最长”匹配，但这里必须有一些方法可以强制变得更懒，对吧？

Answer 1

您应该忽略 ID 第一位的“A”和“N”聊天。正如@CoronA 注意到的那样，ANTLR 尽可能长地匹配令牌（ID 'A10' 的长度大于 DATATYPE_ALPHANUMERIC 'A' 的长度）。另请阅读：Priority rules。尝试使用以下语法：

grammar expr;

compileUnit
    : typedeclaration EOF
    ;

typedeclaration
    : ID LPAREN datatype INT RPAREN
    ;

datatype
    : DATATYPE_ALPHANUMERIC
    | DATATYPE_NUMERIC
    ;

DATATYPE_ALPHANUMERIC
    : 'A'
    ;

DATATYPE_NUMERIC
    : 'N'
    ;

INT
    : DIGIT+
    ;

ID
    : [b-mo-zB-MO-Z] (LETTER | DIGIT)*
;

LPAREN
    : '('
    ;

RPAREN
    : ')'
    ;

WS
    : [ \t\f]+ -> skip
    ;

fragment
DIGIT
    : [0-9]
    ;

fragment
LETTER
    : [a-zA-Z]
    ;

您也可以使用以下语法而不受 id 限制。数据类型将比字母更早被识别。也不清楚：

grammar expr;

compileUnit
    : typedeclaration EOF
    ;

typedeclaration
    : id LPAREN datatype DIGIT+ RPAREN
    ;

id
    : (datatype | LETTER) (datatype | LETTER | DIGIT)*
    ;

datatype
    : DATATYPE_ALPHANUMERIC
    | DATATYPE_NUMERIC
    ;

DATATYPE_ALPHANUMERIC: 'A';
DATATYPE_NUMERIC:      'N';
// List with another Data types.
LETTER:                [a-zA-Z];

LPAREN
    : '('
    ;

RPAREN
    : ')'
    ;

WS
    : [ \t\f]+ -> skip
    ;

DIGIT
    : [0-9]
    ;