Google 表格 SUMIF 文本公式

Question

好吧，我会提前说我在 excel 上不是那么好，在 google 表格上更糟糕。 我想知道是否有一个公式可以检查某人的姓名，然后将该人得到的分数加到他的总数中。非常感谢！

https://docs.google.com/spreadsheets/d/1D4M8Dlao8yFHJulNDff-i2jZJeVGGY_gejbAfzWdhFo/edit?usp=sharing是链接，如果你想查看的话。

Answer 1

我假设您希望 Punti tot. (R:R) 列包含所有 TA Brawl（列 C:C）、Notte (L:L) 和 50 Shades (H:H；在这种情况下，应该检查两个玩家中的任何一个，对吗？) 对于每个玩家。

你可以把这个放在R2 中（不要忘记删除R2下面的所有内容）：

={
  "Punti tot.";
  ARRAYFORMULA(
    IF(
      P3:P = ""; ;
          SUMIF(A3:A; P3:P; C3:C)
        + SUMIF(E3:E; P3:P; H3:H)
        + SUMIF(F3:F; P3:P; H3:H)
        + SUMIF(J3:J; P3:P; L3:L)
    )
  )
}

---

更新：这是另一个使用QUERY 的解决方案，它也是按总分对玩家进行排序：

=QUERY(
  {
    FILTER({A3:A\ C3:C}; A3:A <> "");
    FILTER({E3:E\ H3:H}; E3:E <> "");
    FILTER({F3:F\ H3:H}; F3:F <> "");
    FILTER({J3:J\ L3:L}; J3:J <> "")
  };
  "
    select Col1, SUM(Col2)
    group by Col1
    order by SUM(Col2) desc,
             Col1
    label Col1 'Player',
          SUM(Col2) 'Punti tot.'
  ";
  -1
)

您可能想在O2 中使用它来进行排名：

={
  "Posizioni Finali";
  ARRAYFORMULA(
    RANK(
      FILTER(Q3:Q; Q3:Q <> "");
      FILTER(Q3:Q; Q3:Q <> "")
    )
  )
}

这样，相同数量的积分可以让玩家获得相同的位置。否则 hysen 将获得第 9 名，而 Imurshh 将获得第 10 名，因为 h 排在 i 之前。