如何从 obj 向下转换为 option<obj>？

Question

我有一个接受对象类型参数的函数，需要将其向下转换为option<obj>。

member s.Bind(x : obj, rest) =
    let x = x :?> Option<obj>

如果我将（例如）Option<string> 作为x 传递，则最后一行将引发异常：无法转换类型为 'Microsoft.FSharp.Core.FSharpOption'1[System.String] 的对象' 输入 'Microsoft.FSharp.Core.FSharpOption'1[System.Object]'。

或者，如果我尝试类型测试：

member s.Bind(x : obj, rest) =
   match x with
    | :? option<obj> as x1 -> ... // Do stuff with x1
    | _ -> failwith "Invalid type"

那么x 永远不会匹配option<obj>。

为了完成这项工作，我目前必须指定选项包含的类型（例如，如果函数传递了 option<string>，并且我将参数向下转换为该参数而不是 option<obj>，则该函数有效。

有没有一种方法可以将参数向下转换为 option<obj> 而无需指定选项包含的类型？我尝试了option<_>、option<#obj> 和option<'a>，结果相同。

作为背景，参数需要是obj类型，因为我正在为一个monad写一个接口，所以Bind需要根据实现该接口的monad来绑定不同类型的值。这个特定的 monad 是一个 continuation monad，所以它只是想确保参数是 Some(x) 而不是 None，然后将 x 传递给 rest。 （我需要接口的原因是因为我正在编写一个 monad 转换器，我需要一种方法来告诉它它的参数 monad 实现了绑定和返回。）

更新：我设法通过在选项成为此函数的参数之前向上转换选项的内容来解决这个问题，但我仍然很想知道我是否可以进行类型测试或转换一个对象（或通用参数）到一个选项，而不用担心选项包含什么类型（当然假设强制转换是有效的，即对象确实是一个选项）。

Answer 1

目前没有什么好的方法可以解决这个问题。

问题是您需要在模式匹配中引入一个新的泛型类型参数（当匹配 option<'a> 时），但 F# 只允许您在函数声明中定义泛型类型参数。因此，您唯一的解决方案是使用一些反射技巧。例如，您可以定义一个隐藏此的活动模式：

let (|SomeObj|_|) =
  let ty = typedefof<option<_>>
  fun (a:obj) ->
    let aty = a.GetType()
    let v = aty.GetProperty("Value")
    if aty.IsGenericType && aty.GetGenericTypeDefinition() = ty then
      if a = null then None
      else Some(v.GetValue(a, [| |]))
    else None

这将为您提供None 或Some，其中包含任何选项类型的obj：

let bind (x : obj) rest =   
    match x with    
    | SomeObj(x1) -> rest x1
    | _ -> failwith "Invalid type"

bind(Some 1) (fun n -> 10 * (n :?> int))

Answer 2

我不确定你为什么需要将输入作为 obj，但如果你的输入是 Option<_>，那么很容易：

member t.Bind (x : 'a option, rest : obj option -> 'b) =
    let x = // val x : obj option
        x
        |> Option.bind (box >> Some)
    rest x

Answer 3

回答你的最后一个问题：如果你需要一种通用的方法来检查选项而不预先装箱值，你可以使用 Tomas 代码的轻微变化：

let (|Option|_|) value = 
  if obj.ReferenceEquals(value, null) then None
  else
    let typ = value.GetType()
    if typ.IsGenericType && typ.GetGenericTypeDefinition() = typedefof<option<_>> then
      let opt : option<_> = (box >> unbox) value
      Some opt.Value
    else None
//val ( |Option|_| ) : 'a -> 'b option    

let getValue = function
  | Option x ->  x
  | _ -> failwith "Not an option"

let a1 : int = getValue (Some 42)
let a2 : string = getValue (Some "foo")
let a3 : string = getValue (Some 42) //InvalidCastException
let a4 : int = getValue 42 //Failure("Not an option")