销毁设置为 ShaderEffectSource 的 sourceItem 的项目也会隐藏 ShaderEffectSource

Question

简而言之，我在做什么：

• 我有一个名为snapshotItem 和live: false 的ShaderEffectSource 项目
• 动态实例化一个名为dynamicItem的项目
• 设置snapshotItem.sourceItem = dynamicItem
• 致电snapshotItem.scheduleUpdate()
• 至此，我成功在屏幕上看到了dynamicItem的两个副本
• 在任何键上，我：
  • 将snapshotItem.sourceItem 设置为一个空的虚拟项目，以减少下一步导致问题的可能性
  • 摧毁dynamicItem

问题是当按下一个键时，两个副本都会从屏幕上消失，而我希望 snapshotItem 保留一个。

注意：如果您对实现这一目标的动机感兴趣，请参阅my previous question。

我的代码：

import QtQuick 2.6
import QtQuick.Window 2.2

Window {
    visible: true
    width: 640
    height: 480

    property int childWidth: 100
    property int childHeight: 100

    id: root
    property var dynamicItem

    Item {
        id: dummy
    }

    Component {
        id: dynamicItemComponent
        Rectangle {
            color: "red"
        }
    }

    Component.onCompleted: {
        dynamicItem = dynamicItemComponent.createObject(row);
        dynamicItem.width = childWidth;
        dynamicItem.height = childHeight;
        snapshotItem.sourceItem = dynamicItem;
        snapshotItem.scheduleUpdate();
    }

    Item {
        focus: true
        Keys.onPressed: {
            snapshotItem.sourceItem = dummy;
            dynamicItem.destroy();
        }
    }

    Row {
        id: row
        spacing: 10
        ShaderEffectSource {
            id: snapshotItem
            live: false
            width: childWidth
            height: childHeight
        }
    }
}

Answer 1

您不需要使用dummyItem。您可以将sourceItem 设置为ShaderEffectSource 本身。

也许您应该将recursive 设置为true，但没有它也可以。

import QtQuick 2.6
import QtQuick.Window 2.2

Window {
    visible: true
    width: 640
    height: 480

    property int childWidth: 100
    property int childHeight: 100

    id: root
    property var dynamicItem

    Component {
        id: dynamicItemComponent
        Rectangle {
            color: "red"
        }
    }

    Component.onCompleted: {
        dynamicItem = dynamicItemComponent.createObject(row);
        dynamicItem.width = childWidth;
        dynamicItem.height = childHeight;
        snapshotItem.sourceItem = dynamicItem;
        snapshotItem.scheduleUpdate();
    }

    Item {
        focus: true
        Keys.onPressed: {
            snapshotItem.sourceItem = snapshotItem;
            dynamicItem.destroy();
        }
    }

    Row {
        id: row
        spacing: 10
        ShaderEffectSource {
            id: snapshotItem
            live: false
            // recursive: sourceItem === this
            width: childWidth
            height: childHeight
        }
    }
}